1. sas7bndx are Index files and not SAS data files, so I'll assume you want to ignore those.
2. It sounds like you're doing data exploration by looking at all .sas7bdat files and the variables within. This isn't a method I'd ever recommend and would actually recommend against this. You may not understand the rules behind the variable creation and variables with the same names may not mean the same thing.
3. Generally its faster to query the SASHELP.VCOLUMN Table than to look at the proc contents output.
I'm only accounting for up to 99 different libnames. If you have more, you'll need to modify the program by using z3. or the appropriate number of digits.
The solution requested is below, as well as the query of the sashelp.vcolumn table instead.
The libname function can also be used.
data have;
length path $60.;
path="/july/q2/bc/ringreport/2014/06/bankcard.sas7bndx"; output;
path="/july/q2/bc/ringreport/2014/06/bankcard.sas7bdat"; output;
path="/july/q2/bc/ringreport/2014/06/bank_co.sas7bndx"; output;
path="/july/q2/bc/ringreport/2014/06/bank_co.sas7bdat"; output;
path="/july/q2/bc/ringreport/2014/06/multran.sas7bndx"; output;
path="/july/q2/bc/ringreport/2014/06/multran.sas7bdat"; output;
path="/july/q2/avco/ringreport/2014/06/avco.sas7bndx"; output;
path="/july/q2/avco/ringreport/2014/06/avco.sas7bdat"; output;
path="/july/q2/citiusa/ringreport/2014/06/bankcard.sas7bndx"; output;
path="/july/q2/citiusa/ringreport/2014/06/bankcard.sas7bdat"; output;
path="/july/q2/citiusa/ringreport/2014/06/bank_co.sas7bndx"; output;
path="/july/q2/citiusa/ringreport/2014/06/bank_co.sas7bdat"; output;
run;
data want;
set have;
libpath=substr(path, 1, length(path)-index(reverse(trim(path)), "/"));
extension=scan(path, -1, "/.");
if extension='sas7bndx' then delete;
file=scan(path, -2, '/.');
run;
proc sort data=want; by libpath file;
run;
*create library and run proc contents;
data _null_;
set want;
by libpath;
retain id 0 libref;
if first.libpath then do;
id+1;
libref='temp'||put(id, z2.);
rc=libname('temp'||put(id, z2.), quote(libpath));
end;
file_ref=catx(".", libref, file);
call execute ('proc contents data='||file_ref||';run;');
run;
*get variable information into dataset;
proc sql;
create table column listing as
select a.*, b.path
from sashelp.vcolumn as a
left join sashelp.vlibnam as b
on upper(a.libname)=upper(b.libname)
where upper(a.libname) like 'TEMP%';
quit;
*Clear library references;
data _null_;
set want;
by libpath;
retain id 0;
if first.libpath then do;
id+1;
rc=libname('temp'||put(id, z2.));
end;
run;
Click image to register for webinar
