HASH sort (SAScommunity.org tip-of-the-day 08OCT2013)

[data_null__]

The sascommunity tip of the day is hash sort.

http://www.sascommunity.org/wiki/Tip_of_the_Day:October_8

I thought it might be mildly interesting to generalize it and show an example of CALL VNEXT, my second favorite call routine.:smileysilly:

Not rigorously test your mileage may vary.

%let data=sashelp.class;
%let by=age sex;
%let keep=;
%let out=class;
data _null_;
   if 0 then do;
      set &data(keep=&keep);
      by &by;
      end;
   declare hash srt(dataset:"&data",ordered:'Y',multidata:'Y');
   length _NAME_ $32;
   do _n_ = 1 by 1;
      call vnext(_name_);
      if missing(_name_) then leave;
      if _name_ eq '_NAME_' then leave;
      if _name_ eq: 'LAST.' then continue;
      put (_n_ _name_)(=);
      if _name_ ne: 'FIRST.' then srt.definedata(_name_);
      if _name_ eq: 'FIRST.' then srt.definekey(scan(_name_,-1,'.'));
      end;
   srt.definedone();
   srt.output(dataset:"&out");
   stop;
   run;

[Linlin]

what is your first favorite call routine?

[data_null__]

CALL MISSING of course. :smileylaugh:

[art297]

DN: Do we get a step-by-step explanation so we can discover why it is your second favorite?

[Tom]

Is there something in there that I am missing that will make sure to sort by AGE SEX instead of by SEX AGE ?

[data_null__]

The first variables are in the PDV in the same order as in the BY statement, because there was no prior reference to mess that up.  But we usually refer to LAST. before the SET and BY as in DO UNTIL(LAST....);  Not a problem here.