Turn on suggestions

Auto-suggest helps you quickly narrow down your search results by suggesting possible matches as you type.

Showing results for

- Home
- /
- Programming
- /
- Code examples
- /
- Calculating Elasticities from a Translog Cost Function

Options

- RSS Feed
- Bookmark
- Subscribe
- Printer Friendly Page
- Report Inappropriate Content

- Article History
- RSS Feed
- Bookmark
- Subscribe
- Printer Friendly Page
- Report Inappropriate Content

Views
264

Elasticities of substitution are an important measure of production relationships. When derived demand systems are obtained from a cost function, it is possible to estimate several elasticities of substitution along with price elasticities. For a firm with a single output production function, price elasticity is the percentage change in quantity demanded of an input with respect to a one percent change in the price of the input (own price elasticity) or of another input (cross-price elasticity). This is expressed as:

where η_{ίϳ} is the price elasticity, w_{ϳ} is the price of the ί^{th} input, and x_{ί} is the quantity of the ί^{th} input.

The elasticity of substitution measures the ease with which two inputs can be substituted for one another in the production process. It is mathematically defined as:

where MRTS _{ϳ,ί} is the marginal rate of technical substitution of input ϳ for input ί. Problems arise when this form for the elasticity of substitution is used to describe production processes with more than two inputs. Several other definitions of the elasticity of substitution are explored in the analysis that follows.

This example computes elasticities from a system of derived demand equations obtained from a translog cost function. The translog cost function is

and using Shephard’s lemma, the derived demand equations are

where is the cost share of the ί^{th} input.

For the translog cost function, the price elasticities of demand are

for all and for all ί

Hicks-Allen elasticities of substitution are given by:

for all ί≠ϳ and

for all ί.

Morishima elasticities of substitution are simply computed as:

Some care must be taken when using elasticities of substitution to characterize production relationships. Hicks’ original concept of the elasticity of substitution applied to the case of production with two inputs. In cases with more than two inputs, the Hicks concept can still be applied, but output and all other inputs besides the pair under investigation must be held constant. The Hicks-Allen elasticity presented here (referred to occasionally as the Allen or Allen/Uzawa elasticity) attempts to rectify the inadequacies of the Hicks concept when applied to more than two inputs. As shown, the Hicks-Allen elasticity is a poor measure on this account. What little information the Hicks-Allen elasticity contains can be found in parameter estimates alone. In the case of many factors of production, the best measure of substitution between inputs is the Morishima elasticity. Developed by the economist of the same name, this elasticity is both an exact measure of the ease of substitution and provides complete comparative statics information about relative factor shares. It comes much closer to realizing the goals of Hicks’ original elasticity in the case of many inputs. Both elasticities are calculated in this example to demonstrate the impact of choosing one or another in a given situation.

Data and parameter estimates were previously stored in datasets est and klems in the example "Estimating a Derived Demand System from a Translog Cost Function." The elasticities are evaluated at the sample means, so the MEANS procedure is used to compute the sample mean cost shares and store this information in the dataset meanshares.

```
proc means data = klems noprint mean;
variables sk sl se sm ss;
output out = meanshares mean = sk sl se sm ss;
run;
```

Elasticities are most easily reckoned using the IML procedure as the following statements demonstrate. Because some of the parameters were not estimated, their values must be backed out through the application of the homogeneity and symmetry restrictions.

```
proc iml;
/*Read in parameter estimates*/
use est;
read all var {gkk gkl gke gkm gks};
read all var {gll gle glm gls};
read all var {gee gem ges};
read all var {gmm gms};
close est;
/*Calculate S parameter based on homogeneity constraint*/
gss=0-gks-gls-ges-gms;
/*Read in mean cost shares and construct vector*/
use meanshares;
read all var {sk sl se sm ss};
close meanshares;
w = sk//sl//se//sm//ss;
print w;
/*Construct matrix of parameter estimates*/
gij = (gkk||gkl||gke||gkm||gks)//
(gkl||gll||gle||glm||gls)//
(gke||gle||gee||gem||ges)//
(gkm||glm||gem||gmm||gms)//
(gks||gls||ges||gms||gss);
print gij;
nk=ncol(gij);
mi = -1#I(nk); /*Initialize negative identity matrix*/
eos = j(nk,nk,0); /*Initialize Marshallian EOS Matrix*/
mos = j(nk,nk,0); /*Initialize Morishima EOS Matrix*/
ep = j(nk,nk,0); /*Initialize Price EOD Matrix*/
/*Calculate Marshallian EOS and Price EOD Matrices*/
i=1;
do i=1 to nk;
j=1;
do j=1 to nk;
eos[i,j] = (gij[i,j]+w[i]#w[j]+mi[i,j]#w[i])/(w[i]#w[j]);
ep[i,j] = w[j]#eos[i,j];
end;
end;
/*Calculate Morishima EOS Matrix*/
i=1;
do i=1 to nk;
j=1;
do j=1 to nk;
mos[i,j] = ep[i,j]-ep[j,j];
end;
end;
run;
```

Elasticities are reported in Figure 1.

Price Elasticities of Demand | |||||
---|---|---|---|---|---|

Capital | Labor | Energy | Materials | Services | |

Capital | -0.338 | 0.227 | 0.0183 | 0.0593 | 0.0335 |

Labor | 0.0650 | -0.630 | 0.0315 | 0.231 | 0.303 |

Energy | 0.0606 | 0.364 | -0.0915 | -0.170 | -0.163 |

Materials | 0.0167 | 0.227 | -0.0145 | -0.233 | 0.00367 |

Services | 0.0679 | 2.148 | -0.1000 | 0.0265 | -2.142 |

Hicks-Allen Elasticities of Substitution | |||||
---|---|---|---|---|---|

Capital | Labor | Energy | Materials | Services | |

Capital | -2.993 | 0.575 | 0.536 | 0.148 | 0.600 |

Labor | 0.575 | -1.594 | 0.921 | 0.574 | 5.435 |

Energy | 0.536 | 0.921 | -2.679 | -0.423 | -2.925 |

Materials | 0.148 | 0.574 | -0.423 | -0.579 | 0.0658 |

Services | 0.600 | 5.435 | -2.925 | 0.0658 | -38.437 |

Morishima Elasticities of Substitution | |||||
---|---|---|---|---|---|

Capital | Labor | Energy | Materials | Services | |

Capital | 0 | 0.857 | 0.110 | 0.292 | 2.176 |

Labor | 0.403 | 0 | 0.123 | 0.463 | 2.445 |

Energy | 0.399 | 0.994 | 0 | 0.0627 | 1.979 |

Materials | 0.355 | 0.857 | 0.0771 | 0 | 2.146 |

Services | 0.406 | 2.778 | -0.0084 | 0.259 | 0 |

**Figure 1**: Elasticity Matrices

Own price elasticities of demand are all negative. Using the Hicks-Allen elasticity, all pairs of inputs are substitutes except energy and services and energy and materials. The matrix of Hicks-Allen elasticities is symmetric by design. In general, the degree of substitution is not particularly high except in the case of labor and services. This indicates that the textile industry has responded to increased competition from foreign firms with lower labor costs by substituting away from labor to greater use of services. The Morishima elasticities support this interpretation, but the magnitudes of these elasticities seem more reasonable. Virtually all inputs are substitutes under this measure.

Blackorby, C., and Russell, R. R. (1989). “Will the Real Elasticity of Substitution Please Stand Up? (A Comparison of the Allen/Uzawa and Morishima Elasticities).” American Economic Review 79:882–888.

Chambers, R. G. (1988). Applied Production Analysis: A Dual Approach. New York: Cambridge University Press.

Diewert, W. E., and Wales, T. J. (1987). “Flexible Functional Forms and Global Curvature Conditions.” Econometrica 55:43–68.

Jorgenson, D. (1986). “Econometric Methods for Modeling Producer Behavior.” In Handbook of Econometrics, edited by Z. Griliches, and M. D. Intriligator, 1841–1915. Amsterdam: North-Holland.

**Don't miss out on SAS Innovate - Register now for the FREE Livestream!**

Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.

Article Labels

Article Tags