Creating block randomisation scheme

[Dyllan]

Hello,

I'm trying to create a block randomisation scheme. I've managed to create something very close to what I want, except I would like the subject var to be blank instead of the numbers 1-3. I'm a complete noob when it comes to SAS so any help is much appreciated. I use SAS studo v9.4

Many thanks,

Dyllan

Code:

data _null_;
x=round(ranuni(0)*1000000);
call symput ('seed', x);title "3 arm trial randomisation scheme.";
run;
title "3 arm trial randomisation scheme.";
proc plan;
factors block=100 ordered subject=3 ordered/noprint;
treatments treatment=3 random;
output out=out
treatment cvals=('A' 'B' "C");

run;
proc print data=out noobs;
var block treatment subject;

run;

[ballardw]

You have at least two possible approaches depending on how you will actually use the the out dataset, change the value which will be data step, or a format so the displayed value is blank.

/* to actually change the value*/
data out1;
  set out; 
  call missing (subject);
run;
/* missing may be represented by other characters than .
   to show blank*/
options missing=' ';
proc print data=out1 noobs;
var block treatment subject;

run;
options missing='.';
/* or use a format to change the display*/
proc format library=work;
value blank
low-high=' '
;
run;
proc print data=out noobs;
   var block treatment subject;
   format subject blank.;
run;

If you are going to do this frequently then the format approach may be preferred if using the proc print output. Otherwise use the data change.