Hi:
When I run this report (below) I get the "classterm" repeated at the top of the page in the LISTING and RTF destinations in SAS 9.1.3. HTML, of course, has no page breaks, so COMPUTE BEFORE _PAGE_ only appears at the top of each value for CLASSTERM variable. In SAS 9.1.3, the PDF file only uses the COMPUTE BEFORE _PAGE_ at the beginning of each CLASSTERM. However, in SAS 9.2, PDF and RTF outputs both have the same behavior (with the text string at the top of each page).
I'm not exactly sure of what you're trying to do, but if this program doesn't help you, then you might consider contacting Tech Support for more help.
cynthia
[pre]
** make some data;
data examp;
length classterm $16 specific $16;
set sashelp.class;
classterm='First';
specific = catt('aaa',name);;
output;
specific = catt('bbb',name);
output;
specific = catt('ccc',name);
output;
classterm='Second';
specific = catt('xxx',name);
output;
specific = catt('yyy',name);
output;
specific = catt('zzz',name);
output;
run;
options nodate number pageno=1 ls=80 ps=50;
title; footnote;
ods listing;
ods html file='comp_before_page.html' style=sasweb;
ods rtf file='comp_before_page.rtf' ;
ods pdf file='comp_before_page.pdf';
proc report data=examp nowd;
title 'Use Compute Before Page and Compare Different Destinations';
column classterm specific height;
define classterm / order noprint;
define specific / order;
define height / sum;
break after classterm / summarize page;
compute before classterm;
holdterm = classterm;
endcomp;
compute before _page_;
line 'Term: ' holdterm $16.;
endcomp;
run;
ods _all_ close;
[/pre]