data BACK;
input y group $ sex $ VAR1 $;
cards;
10 A M G
12 A F G
13 A M E
18 B M E
19 B M F
16 C F F
21 C M C
19 C F C
;
proc glmmod data=BACK outdesign=want outparm=p NOPRINT;
class _character_;
model Y = _character_;
run;
* 가변수(Dummy Variable) 생성을 위한 프로그램 생성;
data p1;
set p;
LENGTH VAR $1000.;
var= catT(catx("_", effname, vvaluex(effname)), "= (", EFFNAME ,"= '",vvaluex(effname),"');");
WHERE effname NE 'Intercept';
run;
proc sql;
select var into :Create_dummy separated by " "
from p1;
quit;
%put &Create_dummy;
* 가변수 생성 프로그램 저장;
data _NULL_;
FILE 'D:\SAS DATA\test\가변수생성.sas';
length var $3000.;
var = "&Create_dummy";
put var;
run ;
* 가변수(Dummy Variable) 생성;
DATA BACK1;
SET BACK;
&Create_dummy;
run;
quit;
* 신규 데이터 대한 가변수 처리(기존 변수 CLASS 기준);
DATA BACK2;
SET BACK;
%INCLUDE 'D:\SAS DATA\test\가변수생성.sas';
RUN;
* 참고 SAS 프로그램
- [가변수] How to create dummy variables - Categorical Variables(SAS Communities Library)
: http://cafe.daum.net/statsas/3F8j/337
- [Design matrix] 디자인 행령 생성하기 in SAS (The DO Loop)
: http://cafe.daum.net/statsas/3F8j/336
- [Dummy] 가변수 생성 방법
: http://cafe.daum.net/statsas/3F8j/63
