Your SAS programs, embedded in web apps and elsewhere

Proc Export Error: Excel cannot open the file.

Accepted Solution Solved
Reply
Occasional Contributor
Posts: 13
Accepted Solution

Proc Export Error: Excel cannot open the file.

I am trying to create excel spreadsheet via the stored process by using Proc Export. Log suggests that file has been created without any error but when I try to open the file I get this error:

 

Excel cannot open the file 'myfile.xlsx' because the file format or the file extension is not valid. Verify that the file has not been corrupted or that the file extension matches the format of the file.

 

I am using following code in my stored process to create spreadsheets.

 

%if &Output=EXCEL %then %do;
data _null_;
   rc=stpsrv_header('Content-type','application/vnd.ms-excel');
   rc=stpsrv_header('Content-disposition',"attachment; filename=&geosumlvl._&tabname..xlsx");         
run;

proc export data=Extract_ACS outfile=_webout dbms=xlsx replace;
sheet='mysheet';
run;

%end;

I am wondering if we have a solution to resolve this issue?

 


Accepted Solutions
Highlighted
Solution
‎09-08-2017 09:50 AM
SAS Super FREQ
Posts: 302

Re: Proc Export Error: Excel cannot open the file.

I don't think that PROC EXPORT correctly writes to the _WEBOUT FIILEREF, even though no errors are reported.

 

Try this code and if it works, then you can adapt it to your data:

 

ods _all_ close;

data _null_;
rc=stpsrv_header('Content-type','application/vnd.ms-excel');
rc=stpsrv_header('Content-disposition',"attachment; filename=Class.xlsx");         
run;

%let WORKPATH=%sysfunc(pathname(work));

filename temp "&WORKPATH/temp.xlsx";

proc export data=sashelp.class 
  outfile=temp 
  dbms=xlsx 
  replace;
  sheet='mysheet';
run; quit;

data _null_;
infile temp recfm=f lrecl=1;
file _webout recfm=n;
input;
put _infile_;
run;

 

Vince DelGobbo

SAS R&D

View solution in original post


All Replies
Super User
Posts: 3,238

Re: Proc Export Error: Excel cannot open the file.

What SAS version are you using? XLSX only became available in 9.4M2. Try XLS also.

Super User
Posts: 11,134

Re: Proc Export Error: Excel cannot open the file.

Is your Excel 32-bit or 64-bit? The 32-bit versions don't like opening 64-bit files.

Highlighted
Solution
‎09-08-2017 09:50 AM
SAS Super FREQ
Posts: 302

Re: Proc Export Error: Excel cannot open the file.

I don't think that PROC EXPORT correctly writes to the _WEBOUT FIILEREF, even though no errors are reported.

 

Try this code and if it works, then you can adapt it to your data:

 

ods _all_ close;

data _null_;
rc=stpsrv_header('Content-type','application/vnd.ms-excel');
rc=stpsrv_header('Content-disposition',"attachment; filename=Class.xlsx");         
run;

%let WORKPATH=%sysfunc(pathname(work));

filename temp "&WORKPATH/temp.xlsx";

proc export data=sashelp.class 
  outfile=temp 
  dbms=xlsx 
  replace;
  sheet='mysheet';
run; quit;

data _null_;
infile temp recfm=f lrecl=1;
file _webout recfm=n;
input;
put _infile_;
run;

 

Vince DelGobbo

SAS R&D

☑ This topic is solved.

Need further help from the community? Please ask a new question.

Discussion stats
  • 3 replies
  • 188 views
  • 0 likes
  • 4 in conversation