Regression quadratic point of the maximum response

[RenatoHerrig]

Hi, I need know how I discovery the point of the maximum response in this example of regression quadratic (contrast "quadratica variedade 2" Adubacao(variedade) 0 0 0 0 +1 -1 -1 +1;).

Doing the calculations I know I have a minimum point (y = 2,07 x = 163,33) but I don't know how insert in this program SAS

Thanks.

Data Banzatto182;
input variedade adubacao bloco producao tratamento;
adubacao2=adubacao*adubacao;
cards;
1 0 1 1.65 1
1 0 2 1.68 1
1 0 3 2.12 1
1 0 4 1.68 1
1 100 1 2.14 2
1 100 2 1.36 2
1 100 3 1.31 2
1 100 4 3.13 2
1 200 1 1.40 3
1 200 2 2.16 3
1 200 3 2.00 3
1 200 4 2.00 3
1 300 1 2.32 4
1 300 2 2.42 4
1 300 3 3.43 4
1 300 4 2.46 4
2 0 1 4.22 5
2 0 2 3.50 5
2 0 3 3.80 5
2 0 4 3.05 5
2 100 1 2.21 6
2 100 2 2.78 6
2 100 3 2.30 6
2 100 4 2.34 6
2 200 1 2.30 7
2 200 2 2.00 7
2 200 3 2.16 7
2 200 4 1.72 7
2 300 1 3.43 8
2 300 2 3.18 8
2 300 3 3.30 8
2 300 4 2.90 8
;
proc glm data=Banzatto182;
class tratamento;
model producao= tratamento/ss3;
output out=norma P=pred R=res;
means tratamento /hovtest=bartlett;
run;
proc glm data=Banzatto182;
class variedade adubacao bloco producao;
model producao=bloco variedade adubacao variedade*adubacao/ss3;
lsmeans variedade*adubacao/slice=variedade;
run;
proc glm data=Banzatto182;
class variedade adubacao bloco;
model producao = adubacao(variedade) bloco/ss3;
contrast "linear variedade 1" adubacao(variedade) -3 -1 +1 +3;
contrast "quadratica variedade 1" adubacao(variedade) +1 -1 -1 +1;
contrast "linear variedade 2" Adubacao(variedade) 0 0 0 0 -3 -1 +1 +3;
contrast "quadratica variedade 2" Adubacao(variedade) 0 0 0 0 +1 -1 -1 +1;
run;
proc sort;
by variedade;
proc glm;
by variedade;
model producao = adubacao/ss3;
run;
proc sort;
by variedade;
proc glm;
by variedade;
model producao = adubacao adubacao*adubacao/ss3;
run;

[PGStats · Accepted solution]

proc RSREG is a specialized procedure for finding optimum response. Try this:

proc rsreg Data=Banzatto182;
by variedade;
model producao = adubacao / nocode;
ods output StationaryPoint=minimum;
run;

proc print data=minimum label; run;