BookmarkSubscribeRSS Feed
🔒 This topic is solved and locked. Need further help from the community? Please sign in and ask a new question.
lousam
Obsidian | Level 7

Hello,

 

I need to use stabilized IP weights for my analysis because of the large weights I get when I use the regular IPW (due to large variance). I calculated the regular IPW using the following code:

 

*Calculating probability of participation/no drop out given covariates;

proc logistic data=ipw ;
class gender race income education smoking BMIcat ;
model responder = gender race income education smoking BMIcat;
output out=weights predicted=prob;
run;

*Computing inverse weights;

data inverseweights;
set weights;
if responder=1 then ipw = 1/prob;
if responder=0 then ipw=1/(1-prob);  run;

 

*Merging dataset containing inverse weights with full dataset;

data weight.ipwanalysis;
merge inverseweights fulldataset (in=a);
if a;  by id;  run;

 

*Final Adjusted model weighted by IPW;

proc glm data=ipwanalysis ;
class bmicat race;
model FinalScore=bmicat race age;
weight ipw;
lsmeans bmicat/ stderr pdiff cl; run;  quit;

 

How can I calculate and use Stabilized Inverse Probability Weights (instead of regular IPW) so that I can weight the mean differences I get from my final adjusted model (proc glm). I appreciate any help you can offer

1 ACCEPTED SOLUTION

Accepted Solutions
PGStats
Opal | Level 21

Try replacing your second step with:

 

proc sql;
create table marginalWeights as
select 
    sum(responder) / count(responder) as marginalWeight
from weights;

create table inverseWeights as
select 
    *,
    case responder
        when 1 then marginalWeight / prob
        when 0 then (1 - marginalWeight) / (1-prob)
        else .
        end as ipw
from weights, marginalWeights
order by id;

quit;

(untested)

 

PG

View solution in original post

1 REPLY 1
PGStats
Opal | Level 21

Try replacing your second step with:

 

proc sql;
create table marginalWeights as
select 
    sum(responder) / count(responder) as marginalWeight
from weights;

create table inverseWeights as
select 
    *,
    case responder
        when 1 then marginalWeight / prob
        when 0 then (1 - marginalWeight) / (1-prob)
        else .
        end as ipw
from weights, marginalWeights
order by id;

quit;

(untested)

 

PG

sas-innovate-2024.png

Join us for SAS Innovate April 16-19 at the Aria in Las Vegas. Bring the team and save big with our group pricing for a limited time only.

Pre-conference courses and tutorials are filling up fast and are always a sellout. Register today to reserve your seat.

 

Register now!

What is ANOVA?

ANOVA, or Analysis Of Variance, is used to compare the averages or means of two or more populations to better understand how they differ. Watch this tutorial for more.

Find more tutorials on the SAS Users YouTube channel.

Discussion stats
  • 1 reply
  • 4082 views
  • 2 likes
  • 2 in conversation