Proc Report-Show also categories with no data

[Ronein]

Hello

I am using user defined format in proc report.

I want to see in summary report also categories from proc format that have no data.

So in this example I want that the summary report will include also information about 'China'.

What is the way to do it with proc report?

proc format;
value $ffmt
Europe,USA='Europe_USA'
Asia='Asia_without_China'
China='China'
;
Run;

PROC REPORT DATA=sashelp.CARS NOWD OUT=MyFirstReport;
COLUMNS Type Origin INVOICE=Max_INVOICE INVOICE=Mean_Invoice 
INVOICE=Count_Invoice TEST DriveTrain;
DEFINE Type / Group 'Type of Car' CENTER;
DEFINE Origin / Group 'Origin of Car' CENTER format=$ffmt.;
DEFINE Max_Invoice / ANALYSIS MAX 'Max of Invoice';
DEFINE Mean_Invoice / ANALYSIS MEAN 'Mean of Invoice';
DEFINE Count_Invoice / ANALYSIS N FORMAT=5.0 'Total Number of Cars' center;
DEFINE DriveTrain / ACROSS 'Type of DriveTrain of Car';
DEFINE TEST / COMPUTED 'Number of Cars > Mean(Invoice)' center;
COMPUTE TEST;
     TEST=N(_c7_>Mean_Invoice);
ENDCOMP;
RUN;

[PeterClemmensen]

Use Completerows Option in the PROC REPORT Statement and Preloadfmt in the appropriate Define Statement like this

PROC REPORT DATA=sashelp.CARS NOWD OUT=MyFirstReport completerows;
COLUMNS Type Origin INVOICE=Max_INVOICE INVOICE=Mean_Invoice 
INVOICE=Count_Invoice TEST DriveTrain;
DEFINE Type / Group 'Type of Car' CENTER;
DEFINE Origin / Group 'Origin of Car' CENTER format=$ffmt. preloadfmt;
DEFINE Max_Invoice / ANALYSIS MAX 'Max of Invoice';
DEFINE Mean_Invoice / ANALYSIS MEAN 'Mean of Invoice';
DEFINE Count_Invoice / ANALYSIS N FORMAT=5.0 'Total Number of Cars' center;
DEFINE DriveTrain / ACROSS 'Type of DriveTrain of Car';
DEFINE TEST / COMPUTED 'Number of Cars > Mean(Invoice)' center;
COMPUTE TEST;
     TEST=N(_c7_>Mean_Invoice);
ENDCOMP;
RUN;

[PeterClemmensen]

@Ronein Did this work for you? 🙂