Write it out to multiple datasets and then merge them back together.
data names(keep=col name)
codes(keep=col code)
values(keep=col date value)
;
infile cards dsd dlm='|' truncover ;
retain ncols ;
length col 8 name $100 code $30 date value 8;
format date yymmdd10. ;
informat date ddmmyy10. ;
length dummy $10;
input dummy @ ;
select (dummy);
when ('Name') do;
do col=1 by 1 until (name=' ') ;
input name @;
if name ne ' ' then output names ;
end;
ncols=col-1;
end;
when ('Code') do;
do col=1 to ncols ;
input code @ ;
output codes ;
end;
end;
other do ;
input @1 date @;
do col=1 to ncols;
input value @ ;
output values;
end;
end;
end;
cards;
Name|CHINA NTH.ET.PTL.HDG. DEAD - DELIST.05/04/13|CHINA NORTH EAST - TOTAL ASSETS|CHINA NORTH EAST - CASH DIVIDENDS PAID - TOTAL|XYRATEX
Code|26492K(P)|26492K(WC02999)|26492K(WC04551)|29060T(P)
15-04-2009|1.52|110192|0|2.27
16-04-2009|1.5|110192|0|2.26
17-04-2009|1.5|110192|0|2.4
run;
proc sql noprint ;
create table all as
select b.code,c.date,c.value,a.name
from names a
, codes b
, values c
where a.col = b.col
and b.col = c.col
and a.col = c.col
order by 1,2
;
quit;
