How to assign a Tab name in the Export file after Proc Tabulate?

[ybz12003]

Hi all,

I have a sample code list below.  Is there a way to name the different tabs after getting the Tabulate tables?  Thanks.

ods excel file="Pathway\Dataout_Sites_&tdate..xlsx";

proc tabulate data=Datain1;
  var Total_Cost;
  class class;
  table class*N;
  format class class.;
  where class in (5,6,7,8);
run;

proc tabulate data=Datain2;
  var Lab Radiology Diagnostic_Other;
  class Patient_class;
  table Patient_class * N;
  format Patient_class Patient_class.;
run;

proc tabulate data=Datain3;
  var n;
  class patient_class;
  table patient_class*n*(mean median);
  format patient_clas patient_class.;
run;

ods excel close; 

[PaigeMiller · Accepted solution]

ods excel file="Pathway\Dataout_Sites_&tdate..xlsx" options(sheet_name="DataIn1");

proc tabulate data=Datain1;
  var Total_Cost;
  class class;
  table class*N;
  format class class.;
  where class in (5,6,7,8);
run;

ods excel options(sheet_name="DataIn2");
proc tabulate data=Datain2;
  var Lab Radiology Diagnostic_Other;
  class Patient_class;
  table Patient_class * N;
  format Patient_class Patient_class.;
run;

ods excel options(sheet_name="DataIn3");
proc tabulate data=Datain3;
  var n;
  class patient_class;
  table patient_class*n*(mean median);
  format patient_clas patient_class.;
run;

ods excel close; 

Feel free to use any valid sheet names you want.

[ybz12003]

So, like adding the sheet name in order as below?

ods excel file="Pathway\Dataout_Sites_&tdate..xlsx" options(sheet_name="DataIn1" sheet_name="DataIn2" sheet_name="DataIn3");

[PaigeMiller]

That's not the code I provided. The code I provided should work without modification, if your PROC TABULATE blocks are correct.