Give the Discount to the Last column value

[satya_majhi]

Hi All, I have come across this - 

Jan	Feb	March	Apr
100	200	300	60
100	200		40
100			20

I want to give the discount of the last month sales , I want the last column ( Apr) with this value 

[stat_sas]

Hi,

Not sure, seems like you are trying to create a variable based on 20% of last populated variable value. Please try this.

data want(drop=i);
set have;
array m(*) _numeric_;
do i=1 to dim(m);
   if m(i)>. then Apr=0.2*m(i);
end;
run;

[satya_majhi]

I imported the data and it seems like this,

Then I use the code and I got 

[stat_sas]

Does this work with your initial data set?

[ballardw]

Pictures are not data and your example input is likely incomplete in some form or another.

If you have any other numeric variable in the data set then the array _numeric_ will not give you the result you want. Please see this example:

data have;
   input m1 m2 m3 other;
datalines;
100 200 300 1
100 200 .   2
100 .   .   3
run;

data want(drop=i);
set have;
array m(*) _numeric_;
do i=1 to dim(m);
   if m(i)>. then Apr=0.2*m(i);
end;
run;

If you have any other numeric variables in the data set then the array has to either explicitly name the variable or have a naming convention that will allow a handy list short cut.

See:

data want(drop=i);
set have;
array m(*) m1 m2 m3;
do i=1 to dim(m);
   if m(i)>. then Apr=0.2*m(i);
end;
run;
/* which could be because the variable names are "nice"*/
data want(drop=i);
set have;
array m(*) m:; /* or m1-m3*/
do i=1 to dim(m);
   if m(i)>. then Apr=0.2*m(i);
end;
run;

However there will be problems with this process as it appears that you add a column each month and the code for 1) the array variable list would change and 2) the name of the result variable (Apr) would change. Solutions dealing with that can range from ugly to very fragile depending on the whole process involved.

For extra added fun figure out what happened with the value of Apr from this code:

data have;
   input m1 m2 m3 ;
datalines;
100 200 300 1
100 200 .   2
100 .   .   3
run;

data want(drop=i);
   set have;
   label apr='Discount month';
   array m(*) _numeric_;
   do i=1 to dim(m);
      if m(i)>. then Apr=0.2*m(i);
   end;
run;