Logically, SQL seems easier to code:
DATA product_A;
INPUT A_datetime datetime16. A_price $;
DATALINES;
22JUN11:00:00:04 1.7
22JUN11:00:00:08 1.9
22JUN11:00:00:10 2.3
22JUN11:00:05:12 2.9
22JUN11:00:05:36 3.5
22JUN11:00:32:45 3.2
22JUN11:00:39:01 3.1
22JUN11:00:39:03 2.7
22JUN11:01:10:12 2.6
22JUN11:07:22:10 2.1
26JUN11:12:42:17 3.4
26JUN11:12:42:18 3.6
26JUN11:12:42:21 3.9
;
RUN;
DATA product_B;
INPUT B_datetime datetime16. B_price $;
DATALINES;
22JUN11:00:00:09 0.02
22JUN11:00:05:34 0.07
22JUN11:00:39:05 0.04
26JUN11:12:42:20 0.09
;
RUN;
proc sql;
create table same_trade_times as
select b.b_datetime format=datetime16., b_price, a_datetime format=datetime16., a_price
from product_A a,product_b b, (select max(a_datetime) as adt, b_datetime from product_A ,product_b
where 0 <= b_datetime-a_datetime <= 5
group by b_datetime) c
where a.a_datetime=c.adt and b.b_datetime=c.b_datetime
;
quit;
proc print;run;
Regards,
Haikuo
Edit: it is not too bad if hashing.
data want (drop=_rc);
if _n_=1 then do;
set product_A (obs=1);
format a_datetime datetime16.;
dcl hash h(dataset: 'product_A', ordered:'d');
h.definekey('A_datetime');
h.definedata(all:'y');
h.definedone();
dcl hiter hi('h');
end;
set product_b;
format b_datetime datetime16.;
_rc=hi.first();
do while (_rc=0);
if 0<=b_datetime-a_datetime<=5 then do;
output;
return;
end;
_rc=hi.next();
end;
run;
