Help using Base SAS procedures

check for and delete var

Reply
Contributor
Posts: 40

check for and delete var

Hello,

 

I have the following code that generates an error. I am checking the matrix 'have' for the variable 'cusum'. If 'cusum' exists it is removed. The error I get is: 

 

ERROR 117-185: There was 1 unclosed DO block.

 

	data _null_;
		dsid=open('have');
		check=varnum(dsid,'cusum');

		if check=1 then
			do;
	data have(drop=cusum);
	set have;
	run;
			end;
		run;
Trusted Advisor
Posts: 1,784

Re: check for and delete var

[ Edited ]

You can't have a data step inside a data step. That is the cause of the ERROR message you are seeing.

 

A better way to check to see if a variable exists and then delete it would be:

 

Use PROC SQL to query the DICTIONARY.COLUMNS table to see if the variable exists; and if it exists, then use PROC DATASETS to remove the variable from the data set. This would have to be done in a macro.

 

I'm curious as to why you need to conditionally delete a variable if it exists, as normally leaving an unwanted variable in a data set causes no problems other than taking up slightly more disk space.

Super User
Super User
Posts: 7,695

Re: check for and delete var

Something like the below - although I totally agree with @PaigeMiller, there is rarely a need to delete a variable if you don't know about it up front, sounds like a lack of knowledge about your data.

data _null_;
  set sashelp.vcolumn (where=(libname="WORK" and memname="HAVE" and name="CUSUM"));
  call execute('data work.have; set work.have (drop=cusum); run;');
run;
PROC Star
Posts: 1,290

Re: check for and delete var

[ Edited ]

You don't actually need to check for the existence of the variable. 

 

The system option DKRICOND determines whether or not and error is generated when you drop/keep/rename a variable that doesn't exist.  It's default is DKRICOND=ERROR, but you can set it to NOWARN.

 

data have1;
  x=1;
run;
data have2;
  x=2;
  cusum=1;
run;

options dkricond=error;
data want;
  set have1(drop=cusum)  /*causes error cuz cusum does not exist*/
      have2(drop=cusum)
  ;
  put _all_;
run;


options dkricond=nowarn;
data want;
  set have1(drop=cusum)  /*no error cuz DKRICOND=NOWARN*/
      have2(drop=cusum)
  ;
  put _all_;
run;
options dkricond=error;  *restore the default;
Ask a Question
Discussion stats
  • 3 replies
  • 169 views
  • 0 likes
  • 4 in conversation