Proc Format & Format Char Variables that starts with certain characters

[apple]

Hi

I am new to SAS, so pardon if my question is simple.

I would like to format all my character variables that starts with certain characters. E.G

1) 'ta'

2) '4' (I have numbers that that are stored as character variables)

How do I do that?

Thank you

[Patrick]

Format or recode? If it's format then your question is actually less trivial than you might think.

Can you give us a bit a more extensive sample like a few source strings and to what you would like them formatted or recoded?

[apple]

Hi PAtrick,

Thanks for the reply. It's format.

Eg,

I may have under the variable Name:

'Tan Peter'

'Tan John'

'Mike Tan', ....

I could have many names containing Tan.

I would like to format all Names containing Tan

into 'the Tans' without listing out all the Names.

How can i do so?

Thank you

[Patrick]

Hi @apple

The difference between "recoding" and "formatting":

With recoding you modify the actual internal value of a variable and then assign the result to a new variable.

With formatting you don't change the internal value but just change the way this value gets printed.

I believe you should go for "recoding". Below an example illustrating how this works.

data have;
  infile datalines truncover;
  input name $20.;
  datalines;
Tan Peter
Tan John
Mike Tan
John Doe
Tanner Tolbert
;
run;

/* recode */
data want_recoded;
  set have;
  length name_rec $20;
  if findw(upcase(name),'TAN',' ') then name_rec='the Tans';
  else name_rec=name;
run;

The challenge you're facing with names are different spellings and variations (like Bill and William). With names you normally need first to apply some sort of standardization process.

Below the code sample for "formatting". This code is "advanced" and not what you should be concentrating on if you're "new to SAS".

data have;
  infile datalines truncover;
  input name $20.;
  datalines;
Tan Peter
Tan John
Mike Tan
John Doe
Tanner Tolbert
;
run;

/* format */
proc fcmp outlib=work.funcs.name_recode;
  function name_recode(in_name $) $;
    length out_name $20;
    if findw(upcase(in_name),'TAN',' ') then out_name='the Tans';
    else out_name=in_name;
    return(out_name);
  endsub;
run;

options cmplib=work.funcs;
proc format;
  value $name_group (default=20)
    other = [name_recode()]
  ;
run;

proc print data=have;
  var name;
  format name $name_group.;
run;