Is there a function/format to convert word number to numeric number?

[allaboutsas]

Like from one to 1, two to 2, etc.

[ballardw]

Not as provided as of 9.3. Do have any idea of the range of values represented? It might be possible to create a limited informat or hash look up table if your input data is clean enough.

[art297]

Not that I'm aware of, but you can always roll your own format. If they are just integers you could expand the following to cover the range you need:

data seed;

  length start $100;

  retain fmtname 'wordnum' type 'c';

  do label=1 to 100;

    start=put(label,words100.);

    output;

  end;

  hlo='O';

  label='***ERROR***';

  output;

run;

proc format library=work cntlin=seed;

run;

data have;

  input wordnums $100.;

  cards;

five

six

seven

eight

nine

ten

eleven

twelve

thirteen

fourteen

fifteen

sixteen

seventeen

eighteen

nineteen

twenty

twenty-one

twenty-two

twenty-three

twenty-four

twenty-five

twenty-six

twenty-seven

twenty-eight

twenty-nine

;

data want;

  set have;

  numbers=put(wordnums,$wordnum.);

run;