How to give unique id to group of similar values in a column?

[koya]

data:

accid

====

abc

abc

def

abc

xyz

def

desired output:

accid       uniqid

====      =====

abc            1

abc             1

def              2

abc            1

xyz            3

def             2

[RamKumar]

Try this.

data have;

input accid $;

datalines;

abc

abc

def

abc

xyz

def

run;

proc sort data=have;

by accid;

run;

data want (rename=count=uniqid);

set have;

by accid;

if first.accid then count+1;

else count=count;

run;

[data_null__]

Does

else count=count;

do anything?

[LinusH]

Just by looking in your example, it looks like a surrogate key.

What's the application/requirement? This will just create 1-1 relationships.

If you want to work with lots of data and giving them surrogate keys (and more), look an ETL tool such as DI Studio.

[data_null__]

If you don't want to sort you could do something like this.  If you have multiple keys this will also work by creating a compound index and adding variables to the CLASS statement.

data have;
   input accid $;
   cards;
abc
abc
def
abc
xyz
def
;;;;
   run;

proc summary data=have nway;
   class accid;
   output out=uniqid(drop=_type_ _freq_ rename=(_level_=uniqid) index=(accid)) / levels;
   run;
proc print;
   run;
data withid;
   set have;
   set uniqid key=accid/unique;
   run;
proc print;
   run;

[koya]

Thank you all, that helps!