Help using Base SAS procedures

How to create a table of correlations for many subgroups?

Reply
Occasional Contributor
Posts: 18

How to create a table of correlations for many subgroups?

Dear all SAS experts,

 

I'd like to have a table of correlation between two variables (for example, x and y) by many groups. My dream matrix would like this:

 

GroupNumber      Correlation between x and y

1                              0.5153

2                              0.6

3                              0.3

4                              0.6

5                              0.2

 

I can use BY statement in PROC CORR procedures, but I would get many seperate tables for each subgroup in the BY variable like below (an example result for groupNumber 1), and it's time consuming to build my dream table by hand since it comprosed of more than 100 sugroups each year.

Pearson Correlation Coefficients, N = 8996452
Prob > |r| under H0: Rho=0
 xy
x10.5153
  
y0.51531
  

 

Any suggestions would be appreciated!

SAS Employee
Posts: 106

Re: How to create a table of correlations for many subgroups?

This will give you a table (corr) of all of the coefficients. You'll just need to eliminate the redundant ones. 

 

proc corr data = sashelp.iris;
var petallength sepallength;
by species;
ods output pearsonCorr = Corr; 
run; 

hope this helps.

 

Ray

Occasional Contributor
Posts: 18

Re: How to create a table of correlations for many subgroups?

Thank you for your help

Super User
Posts: 10,020

Re: How to create a table of correlations for many subgroups?

Want IML code ?



proc iml;
use sashelp.iris nobs nobs;
read all var{species petallength sepallength};
close;

start_end=t( loc(t(species) ^= ' '||remove(species,nobs)) )||
          t( loc(t(species) ^= remove(species,1)||' ') );

group=species[start_end[,1]];
corr=j(nrow(group),1,.);
do i=1 to nrow(group);
 idx=start_end[i,1]:start_end[i,2]; 
 temp=petallength[idx]|| sepallength[idx];
 corr[i]=corr(temp)[2];
end;
create want from corr[r=group c={corr}];
append from corr[r=group];
close;
quit;

proc print noobs;run;



OUTPUT:

group	CORR
Setosa	0.26718
Versicolor	0.75405
Virginica	0.86422

SAS Super FREQ
Posts: 3,752

Re: How to create a table of correlations for many subgroups?

[ Edited ]

You can use the NOPRINT and OUT= options to suppress the tables and create a SAS data set that contains the correlations. Then use a DATA step or a WHERE clause to subset the output statistics:

 

proc corr data = sashelp.iris noprint 
          out=outCorr(where=(_TYPE_="CORR"));
by species;
var petallength sepallength;
run; 

proc print data=outCorr label;
where _NAME_="PetalLength";  /* var1 */
var Species                  /* BY var */
    SepalLength;             /* var2 */
label SepalLength="Corr(PetalLength, SepalLength)";
run;

 

 

 

Super User
Posts: 10,020

Re: How to create a table of correlations for many subgroups?

Rick,
It could be simple as :


proc corr data = sashelp.iris noprint 
          out=outCorr(where=(_TYPE_="CORR"));
by species;
var petallength ;
with sepallength;
run; 
proc print noobs;run;

Occasional Contributor
Posts: 18

Re: How to create a table of correlations for many subgroups?

Thank you very much! That's even simpler!

Occasional Contributor
Posts: 18

Re: How to create a table of correlations for many subgroups?

Thank you, that's the dream output I like to have!

Ask a Question
Discussion stats
  • 7 replies
  • 652 views
  • 4 likes
  • 4 in conversation