Help using Base SAS procedures

How do I add endnotes to PROC REPORT

Accepted Solution Solved
Reply
Occasional Contributor
Posts: 10
Accepted Solution

How do I add endnotes to PROC REPORT

[ Edited ]

Hello SAS Community.

 

I am trying to add column heading descriptions in my PROC REPORT. I would use FOOTNOTE statement but I have more than 10 columns to describe so I would exceed the number of footnotes SAS allows. I am looking into the LINE statement. I am having trouble implementing the LINE statement and I am looking for examples to study. I would like to see examples PROC REPORT implementing the LINE statement at the bottom of each page or at the end of the document. All of my column data is display data so there are no compute variables.

 

The LINE statements in the attached SAS code do not start printing in the PDF output until page 7 of the output. I would include the output but I can't release the data to the public.

 

Thanks,

 

Stephen Dybas

 

 


Accepted Solutions
Solution
‎08-10-2016 09:50 AM
Super User
Posts: 11,343

Re: How do I add endnotes to PROC PREPORT

Posted in reply to no_hassles

As far as the "endnotes" goes if you have too many things to fit comfortable into footnotes then perhaps put the information into a data set and use either proc print or report with that data set.

Or use ESCAPECHAR to add additional lines to the footnotes

 

ods escapechar='^';
proc print data=sashelp.class;

footnote1 "This is a foot note ^{newline} that breaks across ^{newline} multiple lines";
footnote2 "and this is the text of footnote2";
run;
footnote;

View solution in original post


All Replies
Solution
‎08-10-2016 09:50 AM
Super User
Posts: 11,343

Re: How do I add endnotes to PROC PREPORT

Posted in reply to no_hassles

As far as the "endnotes" goes if you have too many things to fit comfortable into footnotes then perhaps put the information into a data set and use either proc print or report with that data set.

Or use ESCAPECHAR to add additional lines to the footnotes

 

ods escapechar='^';
proc print data=sashelp.class;

footnote1 "This is a foot note ^{newline} that breaks across ^{newline} multiple lines";
footnote2 "and this is the text of footnote2";
run;
footnote;
SAS Super FREQ
Posts: 708

Re: How do I add endnotes to PROC REPORT

Posted in reply to no_hassles

Find below a sample which shows some additional possibilities to add text to the report

 

ods escapechar="~";
title "This is the title";
footnote1 "FOOTNOTE1 this is the footnote";
footnote2 "FOOTNOTE2 This text~{NEWLINE}is split over two lines";
proc report data=sashelp.cars;
  column origin make model horsepower;
  define origin / order ;
  define make / order;
  define model / display;
  define horsepower / display;

  break after make / page;

  compute after _page_/ style={just=left};
    line "this is the first LINE, after";
    line "this is the second LINE, after";
  endcomp;
  compute before _page_/ style={just=left};
    line "this is the first LINE, before";
    line "this is the second LINE, before";
  endcomp;

run;
Occasional Contributor
Posts: 10

Re: How do I add endnotes to PROC REPORT

Posted in reply to Bruno_SAS
Thank for the response. The ODS escape character worked out as the most flexible. The compute before and after example is also good to know.
☑ This topic is solved.

Need further help from the community? Please ask a new question.

Discussion stats
  • 3 replies
  • 272 views
  • 1 like
  • 3 in conversation