Help using Base SAS procedures

Adding values on a column

Reply
N/A
Posts: 0

Adding values on a column

I have a SAS data set where I have a column of $ values, is there any way
that SAS can add up all the $ values in a column?

I know SAS can add a values in the same row of 2 different columns. But not
sure how I go about adding values in the same column.

Any help is much appreciated.

cheers,
SAS Super FREQ
Posts: 8,864

Re: Adding values on a column

Posted in reply to deleted_user
Hi:
SAS has many report procedures that will work for you. PROC PRINT, with the SUM statement, PROC SQL, PROC MEANS, PROC TABULATE, PROC REPORT. The code below shows MEANS, TABULATE and REPORT methods for producing a summary report from a SAS dataset. If you needed to create an output dataset of summary numbers, then all 3 procedures could do that as well.

It sort of boils down to whether you want an output dataset or an output report. The program below creates 1 HTML file with 3 summary reports based on the PRODUCT and SALES variables in SASHELP.SHOES.

cynthia
[pre]
ods html file='c:\temp\sumval.html' style=sasweb;

proc means data=sashelp.shoes sum;
title 'Proc Means';
class product;
var sales;
run;

proc tabulate data=sashelp.shoes f=dollar16.;
title 'Proc TABULATE';
class product;
var sales;
table product all,
n*f=comma6. sum*(sales);
keylabel n='Count'
sum=' ';
run;

proc report data=sashelp.shoes nowd;
title 'Proc REPORT';
column product n sales;
define product / group;
define n / 'Count' f=comma6.;
define sales / sum f=dollar16.;
rbreak after / summarize;
run;

ods _all_ close;
[/pre]
N/A
Posts: 0

Re: Adding values on a column

Posted in reply to deleted_user
thanks Cynthia, appreciate your help always.
Super User
Posts: 10,023

Re: Adding values on a column

Posted in reply to deleted_user
Hi.
In SAS,there is SUM statement ( i.e variable+increase ) ,
And sum Function also can do it. Just need to continuely cumulate this variable.



Ksharp
Ask a Question
Discussion stats
  • 3 replies
  • 341 views
  • 0 likes
  • 3 in conversation