Data visualization with SAS programming

Using style attribute references in SGPLOT SAS 9.4

Accepted Solution Solved
Reply
Super Contributor
Posts: 252
Accepted Solution

Using style attribute references in SGPLOT SAS 9.4

Hi,

 

I have SAS 9.4 TS Level 1M2. I was wondering if it was possible to use style attribute references within SGPLOT to specify the color of your markers? This is because I like to use the default SAS colors, and in my "real" example, I have several columns, so I will use several scatter statements.

 

I've been using the following code to try and get light red marker symbols, the second color SAS uses in the grouped data, but this doesn't work. I thought it was possible to achieve in SGPLOT in SAS 9.4? I also wanted to avoid using the code of the color, i.e. cx.......

 

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=(symbol=circlefilled color=GraphData2:contrastcolor);
run;

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=(symbol=circlefilled) filledoutlinedmarkers markerfillattrs=(color=GraphData);
run;

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=(symbol=circlefilled color=GraphData2);
run;

 

The following code, does work in GTL, but I wanted to use SGPLOT for this example.

 


proc template;
  define statgraph lineplot;
    begingraph;
      layout overlay;
        scatterplot x = height y = weight / markerattrs=(symbol=circlefilled color=GraphData2:contrastcolor);
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=sashelp.heart template=lineplot;
run;

 

Thank you in advance for your help.

Kriss


Accepted Solutions
Solution
‎03-31-2016 10:51 AM
SAS Super FREQ
Posts: 3,383

Re: Using style attribute references in SGPLOT SAS 9.4

By a happy coincidence, I asked @SanjayM this question a few weeks ago and he taught me the trick: You need to specify the GraphDatan attributes  and then specify the overrides:

 

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=GraphData2(symbol=circlefilled);
run;

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=(symbol=circlefilled) filledoutlinedmarkers markerfillattrs=GraphData1;
run;

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=GraphData2(symbol=circlefilled);
run;

View solution in original post


All Replies
Solution
‎03-31-2016 10:51 AM
SAS Super FREQ
Posts: 3,383

Re: Using style attribute references in SGPLOT SAS 9.4

By a happy coincidence, I asked @SanjayM this question a few weeks ago and he taught me the trick: You need to specify the GraphDatan attributes  and then specify the overrides:

 

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=GraphData2(symbol=circlefilled);
run;

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=(symbol=circlefilled) filledoutlinedmarkers markerfillattrs=GraphData1;
run;

proc sgplot data = sashelp.heart;
  scatter x = height y = weight / markerattrs=GraphData2(symbol=circlefilled);
run;
Super Contributor
Posts: 252

Re: Using style attribute references in SGPLOT SAS 9.4

Oh thank you @Rick_SAS, that's the way to do it! :-)

SAS Super FREQ
Posts: 3,383

Re: Using style attribute references in SGPLOT SAS 9.4

I'm just the messenger, but you are welcome. The real thanks are for Sanjay who provided the information and syntax.Like you, I had tried everything I could think of.

 

I think our confusion is that the syntax GraphData1:ContrastColor is valid in the GTL.

☑ This topic is SOLVED.

Need further help from the community? Please ask a new question.

Discussion stats
  • 3 replies
  • 342 views
  • 2 likes
  • 2 in conversation