Data visualization with SAS programming

Overlaying a panels with line plots

Accepted Solution Solved
Reply
Regular Contributor
Posts: 154
Accepted Solution

Overlaying a panels with line plots

[ Edited ]

I have a vertical bar plot of means by visit number paneled by group.

 

Since I only have a few patients in my sample, I would like to overlay this plot with individual line plots. Is there an easy way to do this?


Accepted Solutions
Solution
‎12-05-2017 01:17 PM
PROC Star
Posts: 1,215

Re: Overlaying a paneled vertical bar chart with line plots

[ Edited ]

If I understand you correctly, then do something like this

 

data have;
input ID$ Visit Group Y;
datalines;
1 1 0 20
2 1 0 24
3 1 1 33
4 1 1 15
5 1 0 26
6 1 1 25
1 2 0 16
2 2 0 12
3 2 1 53
4 2 1 23
5 2 0 10
6 2 1 29
;

proc sql;
	create table help as
	select *
	      ,mean(Y) as VisitMean
	from have
	group by Group, Visit
	order by Group, Visit, ID;
quit;

title "Panel Overlayed With Line Plots";
proc sgpanel data=help;
	panelby Group;
	vbarparm category=visit response=VisitMean;
	series x=Visit y=y / group=ID markers markerattrs=(symbol=circlefilled);
	rowaxis display=(nolabel) grid;
	colaxis display=(nolabel);
run;

View solution in original post


All Replies
PROC Star
Posts: 1,215

Re: Overlaying a paneled vertical bar chart with line plots

Use the SERIES Statement to plot your individual IDs and use the VBARPARM instead of VBAR, since SERIES and VBAR cannot be overlayed. 

 

Also check out Plot Type Compatibility for a nice summary of what plot types can be overlayed in PROC SGPLOT

 

 

PROC Star
Posts: 1,215

Re: Overlaying a paneled vertical bar chart with line plots

Be aware though, that with VBARPARM, you have to calculate the mean values beforehand. 

 

Also, provide some sample of your data to get a code answer Smiley Happy

Regular Contributor
Posts: 154

Re: Overlaying a paneled vertical bar chart with line plots

Sure and thanks!

 

Sample data:

 

ID     Visit     Group     Y

1        1           0         20

2        1           0         24

3        1           1         33

4        1           1         15

5        1           0         26

6        1           1         25

1        2           0         16

2        2           0         12

3        2           1         53

4        2           1         23

5        2           0         10

6        2           1         29

Solution
‎12-05-2017 01:17 PM
PROC Star
Posts: 1,215

Re: Overlaying a paneled vertical bar chart with line plots

[ Edited ]

If I understand you correctly, then do something like this

 

data have;
input ID$ Visit Group Y;
datalines;
1 1 0 20
2 1 0 24
3 1 1 33
4 1 1 15
5 1 0 26
6 1 1 25
1 2 0 16
2 2 0 12
3 2 1 53
4 2 1 23
5 2 0 10
6 2 1 29
;

proc sql;
	create table help as
	select *
	      ,mean(Y) as VisitMean
	from have
	group by Group, Visit
	order by Group, Visit, ID;
quit;

title "Panel Overlayed With Line Plots";
proc sgpanel data=help;
	panelby Group;
	vbarparm category=visit response=VisitMean;
	series x=Visit y=y / group=ID markers markerattrs=(symbol=circlefilled);
	rowaxis display=(nolabel) grid;
	colaxis display=(nolabel);
run;
Regular Contributor
Posts: 154

Re: Overlaying a paneled vertical bar chart with line plots

worked beautifully, thank you!
☑ This topic is solved.

Need further help from the community? Please ask a new question.

Discussion stats
  • 5 replies
  • 229 views
  • 1 like
  • 2 in conversation