BookmarkSubscribeRSS Feed
tc
Lapis Lazuli | Level 10 tc
Lapis Lazuli | Level 10

FastFasterFastest.png

 

Just about time for the closing ceremony, so time for one last chart - a simple dot plot that tries to capture the effect of distance/hurdles on the average speed of the winners of the Men's Track & Field event finals. Was kind of surprised to see how fast those distance walkers go!

 

* Fun w/ODS Graphics: Dot Plot of Men's Track & Field event winners' avg speeds;

data results;
infile cards dlm="," firstobs=2 truncover dsd;
input DISTANCE EVENT : $30. WINNER : $30. COUNTRY : $30. TIME time12.;
MPH=DISTANCE/TIME/1000*60*60*0.621371; * Convert to miles-per-hour for us metric-challenged;
* Source: https://en.wikipedia.org/wiki/Athletics_at_the_2016_Summer_Olympics;
cards;
DISTANCE,EVENT,WINNER,COUNTRY,TIME
100, 100m,Usain Bolt, Jamaica,0:00:09.81
200, 200m,Usain Bolt, Jamaica,0:00:19.78
400, 400m,Wayde van Niekerk, South Africa,0:00:43.03
800, 800m,David Rudisha, Kenya,0:01:42.15
1500, 1500m,Matthew Centrowitz Jr., United States,0:03:50.00
5000, 5000m,Mo Farah, Great Britain,0:13:03.30
10000, 10000m,Mo Farah, Great Britain,0:27:05.17
110, 110m hurdles,Omar McLeod, Jamaica,0:00:13.05
400, 400m hurdles,Kerron Clement, United States,0:00:47.73
3000, 3000m steeplechase,Conseslus Kipruto, Kenya,0:08:03.28
400, 4×100m relay, Jamaica,,0:00:37.27
1600, 4×400m relay, United States,,0:02:57.30
42195, Marathon,Eliud Kipchoge,Kenya,2:08:44.00
20000, 20km walk,Wang Zhen, China,1:19:14.00
50000, 50km walk,Matej Tóth, Slovakia,3:40:58.00
;
ods listing image_dpi=300 gpath='/folders/myfolders';
ods graphics on / reset antialias width=7in height=5in imagename="FastFasterFastest";
proc sgplot data=results;
title "Who's the Fastest of Them All? Winners of Men's Track & Field Event Finals";
dot event / response=MPH categoryorder=respdesc;
yaxis display=(nolabel) valueattrs=(size=7pt);
xaxis label="Average Speed(Mph)" grid labelattrs=(size=7pt)  valueattrs=(size=7pt);
yaxistable mph / title="Mph" position=right nolabel titleattrs=(size=7pt);
yaxistable distance / title="Meters" position=right nolabel titleattrs=(size=7pt);
yaxistable winner / title="Winner" position=right nolabel titleattrs=(size=7pt);
yaxistable country / title="Country" position=right nolabel titleattrs=(size=7pt);
yaxistable time / title="Time" position=right nolabel titleattrs=(size=7pt);
format mph 5.2 time tod11.2 distance comma7.;
run;

 

2 REPLIES 2
Quentin
Super User

Nice plot.

 

Interesting that the 4x100 is faster average speed than the 100m, but the 4x400 is a little slower than the 400.

 

At first I was confused that the average speed of 4x100 could be so much faster than the Usain Bolt's average speed in the 100m.  But I suppose perhaps it is because in the 4x100, three of the four runners get a "running start" instead of starting from the blocks.

BASUG is hosting free webinars Next up: Jane Eslinger presenting PROC REPORT and the ODS EXCEL destination on Mar 27 at noon ET. Register now at the Boston Area SAS Users Group event page: https://www.basug.org/events.
ballardw
Super User

And, to add to @Quentin, there is only reaction time included once at the start. The 3 subsequent runners get to see the oncoming team member and start moving as desired. Cutting out 3 reactions to start could well be nearly .6 seconds overall.

sas-innovate-2024.png

Today is the last day to save with the early bird rate! Register today for just $695 - $100 off the standard rate.

 

Plus, pre-conference courses and tutorials are filling up fast and are always a sellout. Register today to reserve your seat.

 

Register now!

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

Click image to register for webinarClick image to register for webinar

Classroom Training Available!

Select SAS Training centers are offering in-person courses. View upcoming courses for:

View all other training opportunities.

Discussion stats
  • 2 replies
  • 2892 views
  • 7 likes
  • 3 in conversation