Data visualization with SAS programming

Find a Central Zip for a Cluster of Zips

Accepted Solution Solved
Reply
Contributor
Posts: 37
Accepted Solution

Find a Central Zip for a Cluster of Zips

Is there a way to find the central zip of a group of zips? For instance if I am given 30 different zips how can I find the central zip of that cluster?

 

Thanks.


Accepted Solutions
Solution
‎11-10-2015 01:17 PM
Grand Advisor
Posts: 17,360

Re: Find a Central Zip for a Cluster of Zips

[ Edited ]

Take the mean of the latitude and longitude and then find the zip that's the closest? You can find the closest by finding the distance between each zip and your centroid location and the one with the minimum distance would be the central.

GEODIST is a good function that would help with this.

 

Here's an example of how that might work, though it doesn't seem to pick the point I'd expect. Perhaps I did something wrong, but I would expect the methodology to work...

 

*Get random sample of zip codes;
data zips;
set sashelp.zipcode;
where statecode='NY';
if rand('bernoulli', 0.05)=1 then output;
keep zip x y;
run;

*Look at the spatial distribution;
proc sgplot data=zips;
scatter x=x y=y;
run;quit;

*Find centroid of all zips;
proc means data=zips mean noprint;;
var x y;
output out=zip_central mean(x)=mean_x mean(y)=mean_y;
run;

*Find distance from each zip to centroid;
data zips_all;
if _n_ =1 then set zip_central;
set zips;
distance=geodist(y, x, mean_y, mean_x);
distance2= ((x-mean_x)**2 + (y-mean_y)**2)**(0.5);
run;

*Sort so the closest zip to centroid is first;
proc sort data=zips_all;
by distance2;
run;

*Add in to main dataset;
data zip_central;
set zips /*original zip data*/
	zip_central(rename=(mean_x=x mean_y=y)) /*center of zips*/
	zips_all(obs=1 keep=zip x y) /*zip closest to centroid*/
	indsname=source /*option to include datasource name*/;
dname=source;
run;

/*Plot to check answer*/
proc sgplot data=zip_central;
scatter x=x y=y/group=dname;
run;quit;

View solution in original post


All Replies
Solution
‎11-10-2015 01:17 PM
Grand Advisor
Posts: 17,360

Re: Find a Central Zip for a Cluster of Zips

[ Edited ]

Take the mean of the latitude and longitude and then find the zip that's the closest? You can find the closest by finding the distance between each zip and your centroid location and the one with the minimum distance would be the central.

GEODIST is a good function that would help with this.

 

Here's an example of how that might work, though it doesn't seem to pick the point I'd expect. Perhaps I did something wrong, but I would expect the methodology to work...

 

*Get random sample of zip codes;
data zips;
set sashelp.zipcode;
where statecode='NY';
if rand('bernoulli', 0.05)=1 then output;
keep zip x y;
run;

*Look at the spatial distribution;
proc sgplot data=zips;
scatter x=x y=y;
run;quit;

*Find centroid of all zips;
proc means data=zips mean noprint;;
var x y;
output out=zip_central mean(x)=mean_x mean(y)=mean_y;
run;

*Find distance from each zip to centroid;
data zips_all;
if _n_ =1 then set zip_central;
set zips;
distance=geodist(y, x, mean_y, mean_x);
distance2= ((x-mean_x)**2 + (y-mean_y)**2)**(0.5);
run;

*Sort so the closest zip to centroid is first;
proc sort data=zips_all;
by distance2;
run;

*Add in to main dataset;
data zip_central;
set zips /*original zip data*/
	zip_central(rename=(mean_x=x mean_y=y)) /*center of zips*/
	zips_all(obs=1 keep=zip x y) /*zip closest to centroid*/
	indsname=source /*option to include datasource name*/;
dname=source;
run;

/*Plot to check answer*/
proc sgplot data=zip_central;
scatter x=x y=y/group=dname;
run;quit;
Contributor
Posts: 37

Re: Find a Central Zip for a Cluster of Zips

Ok great thank you. You got me on the right path.

☑ This topic is SOLVED.

Need further help from the community? Please ask a new question.

Discussion stats
  • 2 replies
  • 315 views
  • 0 likes
  • 2 in conversation