BookmarkSubscribeRSS Feed
🔒 This topic is solved and locked. Need further help from the community? Please sign in and ask a new question.
AAWTomHanks
Calcite | Level 5

Is there a way to find the central zip of a group of zips? For instance if I am given 30 different zips how can I find the central zip of that cluster?

 

Thanks.

1 ACCEPTED SOLUTION

Accepted Solutions
Reeza
Super User

Take the mean of the latitude and longitude and then find the zip that's the closest? You can find the closest by finding the distance between each zip and your centroid location and the one with the minimum distance would be the central.

GEODIST is a good function that would help with this.

 

Here's an example of how that might work, though it doesn't seem to pick the point I'd expect. Perhaps I did something wrong, but I would expect the methodology to work...

 

*Get random sample of zip codes;
data zips;
set sashelp.zipcode;
where statecode='NY';
if rand('bernoulli', 0.05)=1 then output;
keep zip x y;
run;

*Look at the spatial distribution;
proc sgplot data=zips;
scatter x=x y=y;
run;quit;

*Find centroid of all zips;
proc means data=zips mean noprint;;
var x y;
output out=zip_central mean(x)=mean_x mean(y)=mean_y;
run;

*Find distance from each zip to centroid;
data zips_all;
if _n_ =1 then set zip_central;
set zips;
distance=geodist(y, x, mean_y, mean_x);
distance2= ((x-mean_x)**2 + (y-mean_y)**2)**(0.5);
run;

*Sort so the closest zip to centroid is first;
proc sort data=zips_all;
by distance2;
run;

*Add in to main dataset;
data zip_central;
set zips /*original zip data*/
	zip_central(rename=(mean_x=x mean_y=y)) /*center of zips*/
	zips_all(obs=1 keep=zip x y) /*zip closest to centroid*/
	indsname=source /*option to include datasource name*/;
dname=source;
run;

/*Plot to check answer*/
proc sgplot data=zip_central;
scatter x=x y=y/group=dname;
run;quit;

View solution in original post

2 REPLIES 2
Reeza
Super User

Take the mean of the latitude and longitude and then find the zip that's the closest? You can find the closest by finding the distance between each zip and your centroid location and the one with the minimum distance would be the central.

GEODIST is a good function that would help with this.

 

Here's an example of how that might work, though it doesn't seem to pick the point I'd expect. Perhaps I did something wrong, but I would expect the methodology to work...

 

*Get random sample of zip codes;
data zips;
set sashelp.zipcode;
where statecode='NY';
if rand('bernoulli', 0.05)=1 then output;
keep zip x y;
run;

*Look at the spatial distribution;
proc sgplot data=zips;
scatter x=x y=y;
run;quit;

*Find centroid of all zips;
proc means data=zips mean noprint;;
var x y;
output out=zip_central mean(x)=mean_x mean(y)=mean_y;
run;

*Find distance from each zip to centroid;
data zips_all;
if _n_ =1 then set zip_central;
set zips;
distance=geodist(y, x, mean_y, mean_x);
distance2= ((x-mean_x)**2 + (y-mean_y)**2)**(0.5);
run;

*Sort so the closest zip to centroid is first;
proc sort data=zips_all;
by distance2;
run;

*Add in to main dataset;
data zip_central;
set zips /*original zip data*/
	zip_central(rename=(mean_x=x mean_y=y)) /*center of zips*/
	zips_all(obs=1 keep=zip x y) /*zip closest to centroid*/
	indsname=source /*option to include datasource name*/;
dname=source;
run;

/*Plot to check answer*/
proc sgplot data=zip_central;
scatter x=x y=y/group=dname;
run;quit;
AAWTomHanks
Calcite | Level 5

Ok great thank you. You got me on the right path.

sas-innovate-2024.png

Join us for SAS Innovate April 16-19 at the Aria in Las Vegas. Bring the team and save big with our group pricing for a limited time only.

Pre-conference courses and tutorials are filling up fast and are always a sellout. Register today to reserve your seat.

 

Register now!

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

Click image to register for webinarClick image to register for webinar

Classroom Training Available!

Select SAS Training centers are offering in-person courses. View upcoming courses for:

View all other training opportunities.

Discussion stats
  • 2 replies
  • 1068 views
  • 0 likes
  • 2 in conversation