## Why does prewhitening not change model statistics?

I would require some help on an Arima-Output. If I prewhiten the independet variable ("x") I get the same output as if I do not, this is 2 different inputs, create the same output. Is this the way it's supposed to be and why?

x is supposed to be the independet variable, y is the dependent var. Code:

``````Data D (Keep=x y t);
Retain e1 0 x1 0 x2 0 x3 0
ye 0 y1 0 y2 0;
Do t=-200 To 300;

* y-part: create Armax p=2, xlag=3;
ye=Rannor(9999);
y=150-x3*15+0.2*y1+0.5*y2+ye;
y2=y1;
y1=y;

* x-part: create Arma p=3, q=1;
e=Rannor(1);
x=100+0.5*x1+0.2*x2+0.1*x3-9*e1+e;
e1=e;
x3=x2;
x2=x1;
x1=x;

If t>=1 Then Output;
End;
Run;

Proc Arima Data=D;
* cross correlations with spurious correlations;
Identify Var=y CrossCorr=x;

* prewhiten;
Identify Var=x;
Estimate p=3 q=1;

* estimate y with prewhitening;
Identify Var=y CrossCorr=x;
Estimate p=2 Input=(3\$ x); *-> AIC=3344;

* estimate y without prewhitening;
Identify Var=y CrossCorr=x Clear;
* prewhitening removed -> shouldn't x be different?;
Estimate p=2 Input=(3\$ x); *-> AIC=3344 again (!?);
Run;
``````

Thanks&kind regards

1 ACCEPTED SOLUTION

Accepted Solutions

## Re: Why does prewhitening not change model statistics?

This can indeed be somewhat confusing.  Please refer to the "Prewhitening" subsection of the "Details" section in the ARIMA doc.

When y is a response that is being modeled with x as a predictor, pre-whitening of x is done to help identify the form of the transfer function.  This form is identified by looking at the cross-correlation of pre-whitened y and pre-whitened x.  Once the transfer function form is identified, the pre-whitened series are "essentially" discarded.  The model with y and x is fitted with original y and x  series (and not their prewhitened versions).  There is one issue: when prewhitening is done, the initial parameter estimates  could be based on the prewhitened series but these often lead to the same final parameter estimates.  This explains the behavior you see.

In summary, the output of

Identify Var=y CrossCorr=x;

does depend on whether x and y are prewhitened but the output of

Estimate p=2 Input=(3\$ x);

is essentially independent of prewhitening.

Hope this helps.

2 REPLIES 2

## Re: Why does prewhitening not change model statistics?

This can indeed be somewhat confusing.  Please refer to the "Prewhitening" subsection of the "Details" section in the ARIMA doc.

When y is a response that is being modeled with x as a predictor, pre-whitening of x is done to help identify the form of the transfer function.  This form is identified by looking at the cross-correlation of pre-whitened y and pre-whitened x.  Once the transfer function form is identified, the pre-whitened series are "essentially" discarded.  The model with y and x is fitted with original y and x  series (and not their prewhitened versions).  There is one issue: when prewhitening is done, the initial parameter estimates  could be based on the prewhitened series but these often lead to the same final parameter estimates.  This explains the behavior you see.

In summary, the output of

Identify Var=y CrossCorr=x;

does depend on whether x and y are prewhitened but the output of

Estimate p=2 Input=(3\$ x);

is essentially independent of prewhitening.

Hope this helps.

## Re: Why does prewhitening not change model statistics?

Helps. 🙂
Discussion stats
• 2 replies
• 800 views
• 1 like
• 2 in conversation