Forecasting using SAS Forecast Server, SAS/ETS, and more

Proc Arima forecast output name

Reply
Occasional Contributor
Posts: 19

Proc Arima forecast output name

[ Edited ]

Is there a way I can name the forecasted values from Proc Arima in the out dataset?  For example with Proc Reg I could do something like:

proc reg data=data outest=reg noprint;
name:model y=x;
run;

proc score data=data score=reg type=parms predict out=pred;
var x;
run;

And the forecasted values will be called "name".  Is there a way to do something like this with Proc Arima?  Whenever I use the out statement it stores the forecasts as "forecast of y".

SAS Super FREQ
Posts: 93

Re: Proc Arima forecast output name

the "forecast of y" is actually the lable of the column, not the column name. The standard column name produced by proc arima is FORECAST. You can use the standard sas RENAME statement to change the column name of the output table. For example:

 

/*name the forecast column "xyz"*/

proc arima data=sashelp.air;
    identify var=air(1,12);
    estimate q=(1)(12) noint method=ml;

    forecast id=date interval=month out=b (rename=(forecast = xyz));
run;
quit;

 

SAS Employee
Posts: 416

Re: Proc Arima forecast output name

[ Edited ]
Posted in reply to alexchien

Hello -

In addition to @alexchien's response I'd like to add: as ARIMA creates a common SAS data set one can use utility procedures such as DATASETS to modify attributes such as labels and names. For example if you would like to change both name and label of a variable produced by ARIMA this code snippet might be of interest.

Thanks,

Udo

 

proc arima data=sashelp.air;

identify var=air(1,12);

estimate q=(1)(12) noint method=ml;

forecast id=date interval=month out=work.want;

run;

proc datasets lib=work memtype=data nodetails nolist;

modify want;

attrib forecast label="Hello World";

rename forecast=MYNAME;

quit;

Ask a Question
Discussion stats
  • 2 replies
  • 299 views
  • 0 likes
  • 3 in conversation