How to reference regression coefficients?

[Sunny_Sun]

Hi,

With data A, I run a regression and save coefficients. Then I start to work with data B. I want to reference the saved coefficients using data A. How can I do that in SAS?

Thanks,

Sunny

[ets_kps · Accepted solution]

Hi Sunny,

The closest we have to this in SAS is utilizing item stores for models estimated by certain models. 

Here is an example.

%let nObs = 5000;

%let nVars = 100;

data SimuData;

  array x{&nVars};

  do obsNum=1 to &nObs;

  do j=1 to &nVars;

  x{j}=ranuni(1);

  end;

  linp = 10 + 11*x1 - 10*sqrt(x2) + 2/x3 - 8*exp(x4) + 7*x5*x5

  - 6*x6**1.5 + 5*log(x7) - 4*sin(3.14*x8) + 3*x9 - 2*x10;

  TrueProb = 1/(1+exp(-linp));

  if ranuni(1) < TrueProb then y=1;

  else y=0;

  output;

  end;

run;

proc logistic data=SimuData;

  effect splines = spline(x1-x&nVars/separate);

  model y = splines/selection=stepwise;

  store sasuser.SimuModel;

run;

data test;

  array x{&nVars};

  do j=1 to &nVars;

  x{j}=0.15;

  end;

  drop j;

  output;

run;

proc plm restore=sasuser.SimuModel;

  score data=test out=testout predicted / ilink;

run;

data testout;

  set testout(drop=x1-x&nVars);

run;

proc print data=testout;

run;

You can find other examples here.

SAS/STAT 13.2 User's Guide Example Programs (Sample Library)

[Sunny_Sun]

many thanks!