Forecasting using SAS Forecast Server, SAS/ETS, and more

How to get p-value for predictors in ARIMA model?

Reply
N/A
Posts: 1

How to get p-value for predictors in ARIMA model?

Hi,

I use PROC ARIMA to do time series analysis with intervention. I am interested in p-values for the predictors specified in crosscorr() and input() options for the procedure. I extracted estimate and standard error of predictors, then calculated the t-value. But I can't extract p-value directly. Does anybody know how to extract the p-value directly, or the degree of freedom (or central parameter, if any) for the t distribution? Any suggestion is welcome.

Thanks in advance.

Jean

SAS Employee
Posts: 416

Re: How to get p-value for predictors in ARIMA model?

Hello Jean -

Not sure if this is what you are wondering about, but it might be as easy as adding an ODS output statement to your code.

Thanks,

Udo

Example:

data air;

   input ozone @@;

   label ozone  = 'Ozone Concentration'

         x1     = 'Intervention for post 1960 period'

         summer = 'Summer Months Intervention'

         winter = 'Winter Months Intervention';

   date = intnx( 'month', '31dec1954'd, _n_ );

   format date monyy.;

   month = month( date );

   year = year( date );

   x1 = year >= 1960;

   summer = ( 5 < month < 11 ) * ( year > 1965 );

   winter = ( year > 1965 ) - summer;

datalines;

2.7  2.0  3.6  5.0  6.5  6.1  5.9  5.0  6.4  7.4  8.2  3.9

4.1  4.5  5.5  3.8  4.8  5.6  6.3  5.9  8.7  5.3  5.7  5.7

3.0  3.4  4.9  4.5  4.0  5.7  6.3  7.1  8.0  5.2  5.0  4.7

3.7  3.1  2.5  4.0  4.1  4.6  4.4  4.2  5.1  4.6  4.4  4.0

2.9  2.4  4.7  5.1  4.0  7.5  7.7  6.3  5.3  5.7  4.8  2.7

1.7  2.0  3.4  4.0  4.3  5.0  5.5  5.0  5.4  3.8  2.4  2.0

2.2  2.5  2.6  3.3  2.9  4.3  4.2  4.2  3.9  3.9  2.5  2.2

2.4  1.9  2.1  4.5  3.3  3.4  4.1  5.7  4.8  5.0  2.8  2.9

1.7  3.2  2.7  3.0  3.4  3.8  5.0  4.8  4.9  3.5  2.5  2.4

1.6  2.3  2.5  3.1  3.5  4.5  5.7  5.0  4.6  4.8  2.1  1.4

2.1  2.9  2.7  4.2  3.9  4.1  4.6  5.8  4.4  6.1  3.5  1.9

1.8  1.9  3.7  4.4  3.8  5.6  5.7  5.1  5.6  4.8  2.5  1.5

1.8  2.5  2.6  1.8  3.7  3.7  4.9  5.1  3.7  5.4  3.0  1.8

2.1  2.6  2.8  3.2  3.5  3.5  4.9  4.2  4.7  3.7  3.2  1.8

2.0  1.7  2.8  3.2  4.4  3.4  3.9  5.5  3.8  3.2  2.3  2.2

1.3  2.3  2.7  3.3  3.7  3.0  3.8  4.7  4.6  2.9  1.7  1.3

1.8  2.0  2.2  3.0  2.4  3.5  3.5  3.3  2.7  2.5  1.6  1.2

1.5  2.0  3.1  3.0  3.5  3.4  4.0  3.8  3.1  2.1  1.6  1.3

.    .    .    .    .    .    .    .    .    .    .    .

;

ods OUTPUT ParameterEstimates=work.estimates;

proc arima data=air;

   /* Identify and seasonally difference ozone series */

   identify var=ozone(12)

   crosscorr=( x1(12) summer winter );

   /* Fit a multiple regression with a seasonal MA model */

   /*     by the maximum likelihood method               */

   estimate q=(1)(12) input=( x1 summer winter )

   noconstant method=ml;

   /* Forecast */

   forecast  lead=12 id=date interval=month;

run;quit;

proc print data=work.estimates;run;

Ask a Question
Discussion stats
  • 1 reply
  • 434 views
  • 0 likes
  • 2 in conversation