Desktop productivity for business analysts and programmers

Find Minimum Date of Data

Accepted Solution Solved
Reply
Occasional Contributor
Posts: 12
Accepted Solution

Find Minimum Date of Data

Hi can some one help me I want to bring back the minimum dates for each Ref, please see the table below.

 

I am using SAS Enterprise Guide 7.1

 

 Table_Refs

RefDate
101/01/2017
102/02/2017
201/02/2016
202/03/2016
203/04/2016
204/05/2016
310/04/2015
311/09/2015
404/02/2014
401/02/2016
401/01/2017

 


Accepted Solutions
Solution
‎04-26-2017 03:18 PM
Frequent Contributor
Posts: 93

Re: Find Minimum Date of Data

Alternative, which may be copied and pasted to be used in several systems (e.g. R, SPSS, etc.):

 

data have;
infile cards missover;
input Ref	Date:mmddyy10.;
format date date9.;
cards;
1	01/01/2017
1	02/02/2017
2	01/02/2016
2	02/03/2016
2	03/04/2016
2	04/05/2016
3	10/04/2015
3	11/09/2015
4	04/02/2014
4	01/02/2016
4	01/01/2017
;
run;

PROC SQL;
SELECT REF, MIN(DATE) FORMAT=MMDDYY10. FROM HAVE GROUP BY REF;
QUIT;

View solution in original post


All Replies
Super User
Posts: 1,107

Re: Find Minimum Date of Data

Please try the proc sort and first. approach to get the minimum date for each ref

 

data have;
infile cards missover;
input Ref	Date:mmddyy10.;
format date date9.;
cards;
1	01/01/2017
1	02/02/2017
2	01/02/2016
2	02/03/2016
2	03/04/2016
2	04/05/2016
3	10/04/2015
3	11/09/2015
4	04/02/2014
4	01/02/2016
4	01/01/2017
;
run;

proc sort data=have;
by ref date;
run;

data want;
set have;
by ref date;
if first.ref;
run;


Thanks,
Jag
Solution
‎04-26-2017 03:18 PM
Frequent Contributor
Posts: 93

Re: Find Minimum Date of Data

Alternative, which may be copied and pasted to be used in several systems (e.g. R, SPSS, etc.):

 

data have;
infile cards missover;
input Ref	Date:mmddyy10.;
format date date9.;
cards;
1	01/01/2017
1	02/02/2017
2	01/02/2016
2	02/03/2016
2	03/04/2016
2	04/05/2016
3	10/04/2015
3	11/09/2015
4	04/02/2014
4	01/02/2016
4	01/01/2017
;
run;

PROC SQL;
SELECT REF, MIN(DATE) FORMAT=MMDDYY10. FROM HAVE GROUP BY REF;
QUIT;
Occasional Contributor
Posts: 12

Re: Find Minimum Date of Data

Thank you all for all your help I have used thomp7050 solution and it has worked perfectly

Frequent Contributor
Posts: 93

Re: Find Minimum Date of Data

LOL!  In the future I recommend you mark the actual solution as the solution, and not your own post.Smiley Happy

Occasional Contributor
Posts: 12

Re: Find Minimum Date of Data

Lol I will do mate, I just realised after, as this is the first time I have posted on here. i feel like a right old plonker

Community Manager
Posts: 338

Re: Find Minimum Date of Data

Hi @zdassu,

 

I marked the actual solution as correct for you. I understand an errant slip of the finger!

 

Best,

Shelley

Esteemed Advisor
Posts: 6,646

Re: Find Minimum Date of Data

Still another method, using the MEANS procedure:

proc means data=have noprint nway;
class ref;
var date;
output out=want (drop=_type_ _freq_) min(date)=date;
run;

With large datasets, sorting and using "by" instead of "class" might become necessary if you run out of memory. As long as the cardinality of ref does not exceed memory limitations, class works without prior sorting.

---------------------------------------------------------------------------------------------
Maxims of Maximally Efficient SAS Programmers
☑ This topic is SOLVED.

Need further help from the community? Please ask a new question.

Discussion stats
  • 7 replies
  • 210 views
  • 1 like
  • 5 in conversation