Hi, Rita
It's hard to tell exactly what you need from your post, so I've written a short program that may give an example of some of the stuff you need.
I created a date prompt named "Date_Prompt", and ticked the "Use prompt value throughout project" box.
This program does some manipulation with the date, and then in a different step uses it to select records. Take a look at the program, and try running it, and that will probably bring up a bunch more questions.
Note there are SAS functions DAY, MONTH, and YEAR that return those respective values from a SAS date value.
Tom
data _null_;
/* Get the value of the prompt...treat it as a character string */
DV = "&Date_Prompt.";
/* Convert the character string date to a SAS date value */
Date_Number = input(DV, date9.);
/* This would have worked also...
Date_Number = input("&Date_Prompt.", date9.);
*/
/* This will be the same number, but with a format applied, so it looks like a date when printed */
Date_Number_Formatted = Date_Number;
format Date_Number_Formatted date.;
/* Write all three values to the log */
putlog DV= Date_Number= Date_Number_Formatted=;
/* Set up a global macro variable to use in another step */
%global Date_To_Match;
/* Set the date to a week earlier than the prompt */
Numeric_Date_To_Match = Date_Number - 7;
/* Write it to the log */
/* Should be one week earlier than you specified in your prompt */
putlog Numeric_Date_To_Match=;
/* Store it in the macro variable */
call symput("Date_To_Match", put(Numeric_Date_To_Match, best15.));
run;
/* Now run a PROC SQL as a different step, using the macro variable we just created */
/* 1Mar2004 will find a match, so enter a date of 8Mar2004 when prompted */
proc sql;
create table work.Extract as
select * from sashelp.stocks
where Date = &Date_To_Match.;
quit;
