Char to Numeric with Date Format

[danimian]

Hello,

i have a field date_in with data type character with value for example '15.04.2014 10:15' (DD.MM.YYY HH:MM)

Target field date_out has numeric type.

Is there any SAS date format which match with this format?

or how i can deliver the date in above format?

I just tried some formats with input(date_in, format) but cannot find the wanted format result.

Thanks for your support in advance

[Haikuo]

is this what you are after?

data _null_;

     old='15.04.2014 10:15';

     new=input(old,ANYDTDTM23.);

     put new=datetime23.;

run;

[danimian]

I need text '15.04.2014 10:15' from old in new as date in format DD.MM.YYY HH:MM

[slchen]

PROC FORMAT;
  picture dt low-high='%0d.%0m.%0Y %0H:%0M' (datatype=datetime);
RUN;

data _null_;

     old='15.04.2014 10:15';

     new=input(old,ANYDTDTM23.);

     put new=dt.;

run;

[Haikuo · Accepted solution]

There is no out-of box format for your requirement, except you have to make your own:

proc format;

     picture cus_dtm

           low -  high      =  '%0d.%0m.%Y %0h:%0M'

           (datatype=datetime);

run;

data _null_;

     old='15.04.2014 10:15';

     new=input(old,ANYDTDTM23.);

     put new=cus_dtm20.;

run;

[danimian]

Yes Its working fine now. Thanks a lot.

Best Regards

[kristi_jencks]

My current character value is stored as DD.MM.YYY HH:MM. when changing it to the numeric value.

data _null_;
old='15.04.2014 10:15';
new=input(old,ANYDTDTM23.);
put new=datetime23.;
run;

[AndrewHowell]

One further recommendation:

Store the format somewhere permanently, so it's always available, and you don't have to keep redefining it in each SAS session:

proc format library=corpdata.myfmts;
     picture cus_dtm
           low -  high      =  '%0d.%0m.%Y %0h:%0M'
           (datatype=datetime);
run;

options fmtsearch=(corpdata.myfmts),

data _null_;
     old='15.04.2014 10:15';
     new=input(old,ANYDTDTM23.);
     put new=cus_dtm20.;
run;