I was reading the (attached) article entitled "Log-Link Regression Models for Ordinal Responses" by Blizzard et al published in Open Journal of Statistics, 2013 , 3, 16-25.
Wondering if anyone has SAS syntax for that.
Thank you.
Ashutosh
The response functions used in these models are not the usual cumulative or adjacent logits. When you need to model specialized response functions, you can do so in PROC CATMOD using the RESPONSE statement which has flexible syntax that you can use to define the desired functions. However, note that for specialized response functions, CATMOD uses weighted least squares estimation rather than maximum likelihood estimation. If you want to use maximum likelihood estimation, you will need to fit the model using PROC NLMIXED. This note might be helpful as it shows in the Addendum how the proportional and nonproportional odds models can be fit in that procedure. You could modify this to model the desired functions of the probabilities
For example, these statements fit the unconstrained models shown in Table 3 of the paper. For helpful information on how the RESPONSE statement is constructed, see the example in this note.
data a;
length outcome $6.;
do exp="Yes","No";
do outcome="None","Mild","Severe";
input count @@; output;
end; end;
datalines;
70 20 10
80 15 5
;
proc catmod data=a order=data;
weight count;
response log 0 1 0, 0 0 1;
model outcome=exp / prob pred design param=ref;
contrast 'RR Mild' @1 exp 1 / estimate=exp;
contrast 'RR Severe' @2 exp 1 / estimate=exp;
run; quit;
proc catmod data=a order=data;
weight count;
response 1 -1 0 0, 0 0 1 -1 log 0 1 1, 1 1 1, 0 0 1, 0 1 1;
model outcome=exp / prob pred design param=ref;
contrast 'RR Mild' @1 exp 1 / estimate=exp;
contrast 'RR Severe' @2 exp 1 / estimate=exp;
run; quit;
proc catmod data=a order=data;
weight count;
response 1 -1 0 0, 0 0 1 -1 log 0 1 1, 1 1 1, 0 0 1, 1 1 1;
model outcome=exp / prob pred design param=ref;
contrast 'RR Mild' @1 exp 1 / estimate=exp;
contrast 'RR Severe' @2 exp 1 / estimate=exp;
run; quit;
Thanks much.
Ashutosh
Don't miss out on SAS Innovate - Register now for the FREE Livestream!
Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.
ANOVA, or Analysis Of Variance, is used to compare the averages or means of two or more populations to better understand how they differ. Watch this tutorial for more.
Find more tutorials on the SAS Users YouTube channel.