BookmarkSubscribeRSS Feed
deleted_user
Not applicable
ods pdf file='e:\temp.pdf';
%let ls=130;
%let ps=60;
option mprint pageno=1 nodate ls=&ls ps=&ps FORMCHAR="|_---|+|---+=|-/\<>*" ;
%global LINE BLANK;
data _null_;
call symput('LINE',repeat('-',&ls-1));
call symput('BLANK',repeat(' ',&ls-1));
run;
title1 "&blank";
title2 'SAS' ;
footnote1 'The Power To Know';
footnote2 "&blank";
data _null_;
file print titles linesleft = ll pagesize =&ps linesize = &ls;
put
"SAS"/
"&line"/
"Statistical Analysis System"/
"&blank"/
"SPSS"/
"&line"/
"Statistical Product and Service Solutions"/
"&blank"/;
run;
ods pdf close;

you can run the code first and then help me figure out some questions below
1.I want the font of all those words change to 'Arial'
2.the color of "Statistical Analysis System" change to 'brown',


http://www.pinggu.org/bbs/viewthread.phtid=926456&page=1&fromuid=1142421
2 REPLIES 2
Oleg_L
Obsidian | Level 7
Hi.
Try this code.

[pre]
proc template;

define style tt1;
style celldatasimple /
font_face=arial
foreground=black;
style celldataemphasis from celldatasimple /
foreground=brown;
end;

define table to1;
column a;
define a;
style= tt1;
cellstyle _val_ in ('Statistical Analysis System') as celldataemphasis, 1 as celldatasimple;
end;
end;
run;


ods pdf file='d:\work\temp001.pdf' style=tt1;
%let ls=130;
%let ps=60;
option mprint pageno=1 nodate ls=&ls ps=&ps FORMCHAR="|_---|+|---+=|-/\*" ;
%global LINE BLANK;
data _null_;
call symput('LINE',repeat('-',&ls-1));
call symput('BLANK',repeat(' ',&ls-1));
run;
title1 "&blank";
title2 'SAS' ;
footnote1 'The Power To Know';
footnote2 "&blank";
data _null_; length a $&ls.;
file print ods=(template='to1' variables=(a (label="")));
a='SAS';put a _ods_;
a="&line"; put a _ods_;
a="Statistical Analysis System"; put a _ods_;
a="&blank"; put a _ods_;
a="SPSS"; put a _ods_;
a="&line"; put a _ods_;
a="Statistical Product and Service Solutions"; put a _ods_;
a="&blank"; put a _ods_;
run;
ods pdf close;

[/pre]
deleted_user
Not applicable
thx for your kindness!!:)

sas-innovate-2024.png

Join us for SAS Innovate April 16-19 at the Aria in Las Vegas. Bring the team and save big with our group pricing for a limited time only.

Pre-conference courses and tutorials are filling up fast and are always a sellout. Register today to reserve your seat.

 

Register now!

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

Click image to register for webinarClick image to register for webinar

Classroom Training Available!

Select SAS Training centers are offering in-person courses. View upcoming courses for:

View all other training opportunities.

Discussion stats
  • 2 replies
  • 765 views
  • 0 likes
  • 2 in conversation