The SAS Output Delivery System and reporting techniques

SAS RWI Footnote

Accepted Solution Solved
Reply
Contributor
Posts: 21
Accepted Solution

SAS RWI Footnote

Hi,

 

I am creating a table in the SAS Report Writing Interface. I am using the t.foot_start and t.foot_end method for creating a footnote. Is there a way to prevent the footnote from repeating on every page?

 

Thank you,

Neha.


Accepted Solutions
Solution
‎09-09-2016 07:40 PM
Contributor
Posts: 32

Re: SAS RWI Footnote

http://support.sas.com/techsup/notes/v8/00/888.html says that's simply a warning in the log.  If you wish, you can use the NOQUOTELENMAX option so that you don't see that message. 

View solution in original post


All Replies
Grand Advisor
Posts: 9,682

Re: SAS RWI Footnote

Traditional SAS foonotes and titles persist across procedure outputs. It may be as simple as call start and end with no text (I can't test RWI) to stop previously defined footnotes.

Contributor
Posts: 32

Re: SAS RWI Footnote

If you have text that you want displayed only at the end of the table, you can use the format_text method instead.

 

Below is an example.

 

options nodate;

%macro blank_row;
  t.row_start();
  t.format_cell();
  t.format_cell();
  t.format_cell();
  t.format_cell();
  t.format_cell();
  t.row_end();
%mend blank_row;

proc sort data=sashelp.baseball
          out=sorted_by_team;
  by league team name;
run;

ODS PROCLABEL='1986 Major League Baseball Players';

ODS PDF 
  FILE="/folders/myfolders/Report Writing Interface/1986 Baseball Roster.pdf"
  STYLE=HTMLBlue
  PDFTOC=1;

data _null_;
  set sorted_by_team end=done;
  by league team;
  
  if _n_=1 then  
    do;
      dcl odsout t();
    
        t.title(data: 'Title method shows up at top of every page');
        t.footnote(data: 'Footnote method shows up at bottom of every page');
        
        t.table_start();
        
        * create labels at top of table, first page only! ;
        
        t.head_start();
        
        t.row_start();
        t.format_cell(data: 'League', vjust: 'b', just: 'l');
        t.format_cell(data: 'Team', vjust: 'b', just: 'l');
        t.format_cell(data: 'Player', vjust: 'b', just: 'l');
        t.format_cell(data: 'Position', vjust: 'b');
        t.format_cell(data: 'Major#League#Years#of#Service', split: '#');

        t.head_end();
                
    end;
    
   * only show league and team for first player on each team ;
    
   if first.team then  
     do;
      
       t.row_start();
       t.format_cell(data: league, inline_attr: 'font_weight=bold');
       t.format_cell(data: team, just: 'l', inline_attr: 'font_weight=bold');
       t.format_cell(data: name, just: 'l', inline_attr: 'font_style=italic');
       t.format_cell(data: position);
       t.format_cell(data: yrmajor, just: 'r');
       t.row_end();
     
     end;
   else 
     do;
     
       t.row_start();
       t.format_cell();
       t.format_cell();
       t.format_cell(data: name, just: 'l', inline_attr: 'font_style=italic');
       t.format_cell(data: position);
       t.format_cell(data: yrmajor, just: 'r');
       t.row_end();
    
     end;
     
  * only want blank line between teams in report. ;
  * no need for blank line after last team in report. ;
  
  if last.team and not done then 
    do;
      
      %blank_row
      
    end;
    
  if done then  
    do;
    
      t.table_end();
      
      t.format_text(data: 
      'This report is for the active players during the 1986 Major League Baseball season', 
      style_elem: "SystemFooter" );
      
      t.format_text(data: 
      'This text only shows up at bottom of table.  Not the same as a footnote!',
      style_elem: "SystemTitle");
      
      t.note(data: "Link to Report Writing Interface online documentation",
             url:  
        "http://support.sas.com/documentation/cdl/en/odsadvug/67923/HTML/default/viewer.htm#n0w8et93ubh1enn1f34empn5948l.htm");
      
    end;
run;

ODS PDF CLOSE;
Contributor
Posts: 21

Re: SAS RWI Footnote

Is there an option in RWI to include a paragraph of text?

 

My current code is "

t.format_text (text: " TEXT HERE" );

 

But the log gives me a warning saying the

The quoted string currently being processed has become more than 262 characters long.

You might have unbalanced quotation marks.

 

Thanks,

Neha.

 

 

Solution
‎09-09-2016 07:40 PM
Contributor
Posts: 32

Re: SAS RWI Footnote

http://support.sas.com/techsup/notes/v8/00/888.html says that's simply a warning in the log.  If you wish, you can use the NOQUOTELENMAX option so that you don't see that message. 

Post a Question
Discussion Stats
  • 4 replies
  • 429 views
  • 0 likes
  • 3 in conversation