The SAS Output Delivery System and reporting techniques

Proc report

Reply
SAS Employee
Posts: 105

Proc report

Hi,
Is there a way to give a style only to the values of the 'TOTAL'.?

proc report data=a nowindows headskip ;
column visit_char (n);
define visit_char/group ;
rbreak after/summarize style={foreground=blue};
/*-this option also highligths the 'TOTAL'.....*/
compute after;
visit_char='Total' ;
endcomp;
where visit in(0,1,2) and code in(314,303);
quit;

ODS RTF close ;
SAS Super FREQ
Posts: 8,744

Re: Proc report

Hi:
Investigate the use of the CALL DEFINE statement to selectively change a column's style attributes based on the value of the automatic break variable, _BREAK_.

cynthia
[pre]
data a;
set sashelp.prdsale;
visit_char = region;
run;

ODS RTF file='c:\temp\visit.rtf';
proc report data=a nowindows headskip ;
column visit_char (n);
define visit_char/group ;
define n/'N';
rbreak after/summarize;
/*- the CALL DEFINE statement highlights the total value of N */
compute n;
if _break_ = '_RBREAK_' then do;
call define(_COL_,'style','style={foreground=blue}');
end;
endcomp;
compute after;
visit_char='Total' ;
endcomp;
quit;

ODS RTF close ;
[/pre]
SAS Employee
Posts: 105

Re: Proc report

OK Cynthia,
I will check it, Thank for your help !!
Ask a Question
Discussion stats
  • 2 replies
  • 129 views
  • 0 likes
  • 2 in conversation