Accepted Solutions
You do need to do some work yourself, I am not going to go through every combination with an answer 
Maybe something like:
data have;
infile datalines dlm="," dsd;
input name $ age a b c d;
datalines;
alan,12,59.44,45.17,3,4
barb,13,,,,
carl,14,67.23,69.65,,
;
run;
data loop;
set have;
length vlist $2000;
array v{4} a b c d;
do i=1 to 4;
if v{i} ne . then vlist=catx(' ',vlist,vname(v{i}));
end;
if vlist ne "" then
call execute('proc report data=have nowd;
where name="'||strip(name)||'";
columns name age '||strip(vlist)||';
run;');
run;
Hi:
As others have pointed out, without some sample data to test or seeing the program you've already tried, it is hard to make a constructive suggestion.
However, you can assign value to a column in PROC REPORT conditionally. Please see these results for some fake data:
As you can see in #1, the value of the column (cleverly named a_or_b) is either the value or A or the value of B based on a comparison. If you did not want to see the original A or the original B on the report, then you can use NOPRINT, as shown in report #2. However, if the goal is to have an output data set with a new column whose value is conditionally assigned, then the DATA step approach is all you need.
cynthia
** here is the code;
data new;
infile datalines;
input name $ age a b;
datalines;
alan 12 59.44 45.17
barb 13 51.21 54.14
carl 14 67.23 69.65
edna 15 69.51 72.38
fred 16 68.99 60.95
;
run;
footnote 'Yellow means A was GT B; Pink means A LE B';
proc report data=new;
title '1) showing all columns';
column name age a b a_or_b;
define name / order;
define a / display;
define b / display;
define a_or_b / computed f=7.2;
compute a_or_b;
if a gt b then do;
a_or_b = a;
call define(_col_,'style','style={background=lightyellow}');
end;
else if a le b then do;
a_or_b = b;
call define(_col_,'style','style={background=lightpink}');
end;
endcomp;
run;
proc report data=new;
title '2 Using NOPRINT';
column name age a b a_or_b;
define name / order;
define a / display noprint;
define b / display noprint;
define a_or_b / computed;
compute a_or_b;
if a gt b then do;
a_or_b = a;
call define(_col_,'style','style={background=lightyellow}');
end;
else if a le b then do;
a_or_b = b;
call define(_col_,'style','style={background=lightpink}');
end;
endcomp;
run;
You do need to do some work yourself, I am not going to go through every combination with an answer
Maybe something like:
data have;
infile datalines dlm="," dsd;
input name $ age a b c d;
datalines;
alan,12,59.44,45.17,3,4
barb,13,,,,
carl,14,67.23,69.65,,
;
run;
data loop;
set have;
length vlist $2000;
array v{4} a b c d;
do i=1 to 4;
if v{i} ne . then vlist=catx(' ',vlist,vname(v{i}));
end;
if vlist ne "" then
call execute('proc report data=have nowd;
where name="'||strip(name)||'";
columns name age '||strip(vlist)||';
run;');
run;
Don't miss out on SAS Innovate - Register now for the FREE Livestream!
Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.
Click image to register for webinar
Classroom Training Available!
Select SAS Training centers are offering in-person courses. View upcoming courses for:
-
5571 views
-
2 likes
-
-
