ODS Tagsets.Excelxp proc tabulate format totals to bold

[cxkev182]

Hi All,

I am outputting a proc tabulate to excel via ods tagsets.Excelxp.

Is there a way I can make the grand total row and column bold?

Example below:

ods tagsets.ExcelXP file=fileout style=normal;

proc tabulate data=sashelp.shoes;
class product region / missing;
var sales;
table product all='Grand Total',
sales * (region all='Grand Total') * {style={tagattr='format:#,##0.00'}};
run;

ods _all_ close;

Kind Regards,

cxkev

[Miracle · Accepted solution]

Hi, something like this? 

ods tagsets.excelxp path='c:\users\desktop' file='shoes.xml' style=normal; 
proc tabulate data=sashelp.shoes style={tagattr='format:#,##0.00'}; 
	class product region / missing; 
	var sales ; 
	table product all='grand total'*{style=<parent>}, 
	      sales*(region all='grand total'*{style=<parent>});  
	keyword  all / style={font_weight=bold tagattr='format:#,##0.00'};
run; 
ods _all_ close;

[cxkev182]

Thank you very much. That makes the totals bold. Is there a way to right align the figures, as this code left aligns them?

Kind Regards,

[Miracle]

Sorry for the late reply. Please see below updated code in regards to your concern. HTH.

ods tagsets.excelxp path='c:\users\desktop' file='shoes.xml' style=normal; 
proc tabulate data=sashelp.shoes style=[tagattr='format:#,##0.00']; 
	class product region / missing; 
	var sales;
	table product all='Grand Total'*{style=[font_weight=bold tagattr='format:#,##0.00']}, 
	      sales*(region all='Grand Total'*{style=[font_weight=bold tagattr='format:#,##0.00']}); 
run; 
ods _all_ close;

[cxkev182]

Excellent thanks again