ODS RTF gap between tables

[soham]

Hi,
I am trying produce the output with multiple tables on each page. I want them to one after another without any gap.
I did try to use below code. But still not able to achieve.
I didn't know whether PAGEPANELS and TABLESROWS will do anything.
Could you please help me?


proc template;
define style test2;
parent=styles.rtf;
style parskip / fontsize = .01in;
end;
run;
ods rtf style = test2 ;
proc report data = sashelp.class (obs =10) nowindows headline headskip;
run;
ods rtf startpage = no style = test2;
proc report data = sashelp.cntainer nowindows headline headskip;
compute before _page_;
Line " Containers data";
endcomp;
run;
ods rtf close;
ods listing;

Srisoham

[Cynthia_sas]

Hi:
I do not know whether you can have a PARSKIP value of 0 -- I believe it is the PARSKIP element that controls the amount of space between tables, as described here:
http://support.sas.com/rnd/base/new92/92measuredrtf.html#para

When I modify that program, I cannot use a font less than 1pt as the value for PARSKIP, so I suspect that might be the tiniest space you can get. Aren't you seeing an error message someplace in your log -- like this????
ERROR: Integer divide by zero.
ERROR: Termination due to Floating Point Exception


cynthia
[pre]
ods listing close;


proc template;
define style test2;
parent=styles.rtf;
style parskip / fontsize = 1pt;
end;
run;


ods tagsets.rtf file="c:\temp\mparskip.rtf"
OPTIONS(SECT="NONE") STARTPAGE=NO style=test2;

title "Test Title";
footnote "Test Footnote";

proc report data=sashelp.class (obs=5) nowd;
compute before _page_;
line 'CLASS';
endcomp;
run;

proc report data=sashelp.shoes (obs=5) nowd;
compute before _page_;
line 'SHOES';
endcomp;
run;

proc report data=sashelp.cars (obs=5) nowd;
column Make Model Type Origin DriveTrain MSRP Invoice;
compute before _page_;
line 'CARS';
endcomp;
run;

ods _all_ close;
ods listing;
[/pre]

[soham]

Hi Cynthia,
The code looks fine and worked like charm. I made a small change.

style parskip / fontsize = .1pt;


I try to used without TAGSETS. But it is not working as it did with TAGSETS.

Does it really works with TAGSETS only?

Thanks,
Srisoham

[Cynthia_sas]

Hi:
You mean you tried to use your new style with just ODS RTF or ODS PDF or ODS HTML instead of TAGSETS.RTF??? I think that PARSKIP was explicitly designed to work with TAGSETS.RTF --and not for original ODS RTF.

For original ODS RTF, I think the default space between tables is 2 or 4 carriage returns....and I think for original ODS RTF, you still get a section break between each table.

So, if that's what you mean, then yes, I believe that a changed PARSKIP works with TAGSETS.RTF destination.

cynthia

[soham]

Hi Cynthia,
Yes. I try to use it in general ODS RTF or ODS PDF or ODS HTML. Output is generated with breaks between tables. PARSKIP is working in ODS RTF without any impact on output.
Thanks very much for you help.
Srisoham