The SAS Output Delivery System and reporting techniques

How can i get the footnote in last in the pdf file

Reply
Occasional Contributor
Posts: 9

How can i get the footnote in last in the pdf file

using text= option in ods pdf statement i got it in last page, but some times is displayed on next page ( i.e, not in the last page).

SAS Employee
Posts: 5

Re: How can i get the footnote in last in the pdf file

If you are using PROC REPORT, I would suggest using COMPUTE AFTER logic with a LINE statement, or POSTTEXT like the sample code below shows.  If you are not using REPORT, you can use PROC TEMPLATE to get similar results.

Notes/Caveats:

  • pagination on the last page is NOT guaranteed, since observation counts can make this text flow to the next page.
  • using POSTTEXT works on a TABLE basis, so if your PROC step paginates (PRINT/PAGEBY or REPORT with BY or break after group_order_var_here / pageSmiley Wink then the POSTTEXT text will repeat on each of these pages (ie TABLEs).
  • only footnotes will sit at the very bottom of the PDF page. Newline or other inline commands can be used to move other text "down" on the page, but this will require knowing how many observations are on the last page.


If you have followup questions, please email them to support@sas.com with your LOG and PDF file and we'll be happy to investigate further.

ods escapechar="^";

proc template;
 define style mystyle;
  parent=styles.printer;
   style table from output / 
    posttext="^{style systemtitle NON REPORT table}"
     frame=void rules=groups ;
end;
run;


options nodate nonumber orientation=portrait;
title "title";
footnote "footnote";
ods pdf file="c:\temp\not_report.pdf" notoc style=mystyle;

proc print noobs data=sashelp.cars 
/*style(report)={frame=void rules=groups posttext="This is posttext"}*/
style(header)={background=white};
var origin make model;
run;

ods pdf close;

options nodate nonumber orientation=portrait;
title "title";
footnote "footnote";
ods pdf file="c:\temp\report.pdf" notoc;

proc report nowd data=sashelp.cars 
style(report)={frame=void rules=groups posttext="^{style systemtitle This is posttext}"}
style(header)={background=white}
style(lines)=systemtitle;
col origin make model;
define origin / group;
compute after ;
 line "Text to mimic footnote";
endcomp;
run;

ods pdf close;
Ask a Question
Discussion stats
  • 1 reply
  • 700 views
  • 0 likes
  • 2 in conversation