The SAS Output Delivery System and reporting techniques

Generate report in two pages

Reply
Contributor
Posts: 27

Generate report in two pages

Hi all,

How can I report the below data state wise (AP KA TN) in two pages in stead of three; AP and KA data should be in one page and TN data in another page.
plz check. I have written the program like that.(displaying in three separate pages)
data prod_sales;
input state $ pcode $ area $ month stock sale;
cards;
AP N79 HYD 1 40 20
TN N79 CHN 1 30 10
KA N79 BAN 1 45 20
AP N79 HYD 2 30 15
TN N79 CHN 2 10 10
KA N79 BAN 2 45 30
TN N79 CHN 3 20 10
KA N79 BAN 3 25 20
AP N79 HYD 3 20 15
;
proc report data=prod_sales nowd headline;
define state/order;
define area/order;
define pcode/order;
break after state/page;
compute after state;
line 65*'-';
line 'End of the report';
endcomp;
compute before _page_;
line 'This report belongs to: ' state $6.;
endcomp;
run;

Thanks in advance
Super User
Posts: 10,028

Re: Generate report in two pages

Hi.
Because of ' break after state/page;' ,You have three value so have three pages.
Want two page is easy to make a break variable.



[pre]
data prod_sales;
input state $ pcode $ area $ month stock sale;
if state='TN' then page=1;
else page=0;
cards;
AP N79 HYD 1 40 20
TN N79 CHN 1 30 10
KA N79 BAN 1 45 20
AP N79 HYD 2 30 15
TN N79 CHN 2 10 10
KA N79 BAN 2 45 30
TN N79 CHN 3 20 10
KA N79 BAN 3 25 20
AP N79 HYD 3 20 15
;
ods pdf file='c:\test.pdf' style=sasweb;
proc report data=prod_sales nowd headline;
column page state area pcode;
define page /group noprint;
define state/order;
define area/order;
define pcode/order;
break after page/page;
compute after state;
line 65*'-';
line 'End of the report';
endcomp;
compute before _page_;
line 'This report belongs to: ' state $6.;
endcomp;
run;
ods pdf close;


[/pre]
N/A
Posts: 0

Re: Generate report in two pages

hello,

I will add to KSharp's solution the use of proc format so the title changes a little bit:

[pre]
data prod_sales;
input state $ pcode $ area $ month stock sale;

s=ifn(state in ('AP','KA'),1,2);

cards;
AP N79 HYD 1 40 20
TN N79 CHN 1 30 10
KA N79 BAN 1 45 20
AP N79 HYD 2 30 15
TN N79 CHN 2 10 10
KA N79 BAN 2 45 30
TN N79 CHN 3 20 10
KA N79 BAN 3 25 20
AP N79 HYD 3 20 15
;

proc format;
value s
1='AP,KA'
2='TN';
run;

proc report data=prod_sales nowd headline;

column s state pcode area month stock sale;

define state/order;
define area/order;
define pcode/order;
define s/group noprint;

break after state/summarize;

break after s/page;

compute after s;
line 65*'-';
line 'End of the report';
endcomp;

compute before _page_;
line 'This report belongs to: ' s s.;
endcomp;

run;
[/pre]

Marius
Contributor
Posts: 27

Re

Thanks!!!!!!!!! Its running
Ask a Question
Discussion stats
  • 3 replies
  • 177 views
  • 0 likes
  • 3 in conversation