Join Now

SAS Forum Plus 2015: Hands-on workshop: Dan dine egne grafer med ODS Graphics Template Language

by SAS Employee GeorgMorsing on ‎10-07-2015 05:27 AM (311 Views)

Præsentation nummer 14 af Søren Dalsgaard, SAS Institute
9. oktober 2015

 

Beskrivelse:

ODS Graphics Template Language (GTL) er det nye ”sprog”, som benyttes til at lave grafer med i SAS version 9. Deltag på denne workshop og lær at lave dine egne grafer med ODS GTL. Har du først udviklet en ny graf, så kan du genbruge den på forskellige tabeller og kolonner. Proceduren TEMPLATE benyttes til at definere nye GTL-grafer.

Comments
by SAS Employee sdksda
on ‎10-12-2015 03:10 AM

Her er det fulde kode eksempel og et ekstra link

 

http://blogs.sas.com/content/graphicallyspeaking/

 

 

 

by SAS Employee sdksda
on ‎10-12-2015 03:10 AM

proc template;
 define statgraph sda_histogram;
  MVAR COLUMN DATETIME NOBS MEAN INFO;
  begingraph;
   entrytitle "Histogram af " COLUMN;
   entryfootnote halign=right DATETIME;
   layout overlay;
    histogram COLUMN;
    densityplot COLUMN / normal() name="n" legendlabel="Normal";
    densityplot COLUMN / kernel() name="k" lineattrs=(color=coral) legendlabel="Kernel";
    discretelegend "n" "k";

    if (INFO in ('TRUE')) layout gridded / columns=1 autoalign=(topright topleft);
    entry halign=left "Info" / textattrs=(weight=bold);
    layout gridded / columns=2 border=true;
     entry halign=left "Rækker";
     entry halign=right NOBS;
     entry halign=left "Gennemsnit";
     entry halign=right MEAN;
    endlayout;
   endlayout;
   ENDif;
endlayout;
  endgraph;
 end;
run;

%macro sda_graph(ds, column, info);
    %local datetime nobs mean;
 %let datetime = %sysfunc(putn(%sysfunc(datetime()), datetime13));

 proc univariate noprint data=&ds normaltest;
  var &column;
  output out=stats n=nobs mean=mean;
 run;

 data _null_;
  set stats;
  call symputx("nobs",nobs);
  call symputx("mean",put(mean,12.3));
 run;

 proc sgrender data=&ds.
  template=sda_histogram;
 run;

%mend;

%sda_graph(sashelp.class, weight, TRUE);
%sda_graph(sashelp.cars, cylinders, FALSE);