setting length of character variables without changing order

[archita]

i have a dataset with more than 100 variables , I want to set the length of all character variables without changing their order. how to get this ?

[andreas_lds · Accepted solution]

---

@archita wrote:

i have a dataset with more than 100 variables , I want to set the length of all character variables without changing their order. how to get this ?

---

Do you want to change all variable to have the same length?

Do you know how to change the length of one variable?

[archita]

i want to change all the variable to same length without changong their order

[andreas_lds]

proc sql seems to be a good choice to solve the problem.

/* create a dataset that can be modified */
data work.class;
   set sashelp.class;
run;

/* the view will contain all char-variables ordered by their appearance in the dataset */
proc sql noprint;
   create view work.vars as
      select Name
         from sashelp.vcolumn
            where Libname = 'WORK'
               and MemName = 'CLASS'
               and Type = 'char'
         order by Varnum
   ;
quit;

/* creates and executes a proc-sql-step setting the length of all char-variables to 42 - the generated code is written to the log */
data _null_;
   set work.vars end= jobDone;

   if _n_ = 1 then do;
      call execute('proc sql noprint;');
      call execute('alter table work.class');
      call execute('modify ');
   end;
   
   call execute(catx(' ', Name, 'char(42)', ifc(not JobDone, ',', '')));

   if jobDone then do;
      call execute('; quit;');
   end;
run;

[archita]

I need it only by data step.

[FreelanceReinh]

---

@archita wrote:
I need it only by data step.

---

This is similar to @andreas_lds's approach:

data _null_;
call execute('data have; length');
do until(last);
  set sashelp.vcolumn end=last;
  where libname='WORK' & memname='HAVE';
  call execute(catx(' ',name,ifc(type='char','$42',put(length,1.))));
end;
call execute('; set have; run;');
stop;
run;

[PeterClemmensen]

Should all character variables have the same length?

[archita]

yes