The most basic reason is because you are defining the arrays using the variables in COLUMNS_INFO (the proc contents output dataset) and not the variables in the dataset that you ran PROC CONTENTS on to create the COLUMNS_INFO dataset.
For example for WORK.BANANA the set of variables is:
# Variable Type Len Format
1 banana Num 8
2 fruit Num 8
3 date Num 8 YYMMDDN8.
4 customer Char 200
But for COLUMNS_INFO the set of variables is:
# Variable Type Len Label
1 NAME Char 32 Variable Name
2 TYPE Num 8 Variable Type
And the content of COLUMNS_INFO is:
Obs NAME TYPE
1 banana 1
2 customer 2
3 date 1
4 fruit 1
So when you run this code:
data column_types;
set columns_info;
array char_cols[*] _character_;
array num_cols[*] _numeric_;
Both arrays will have only one variable in them. NAME for CHAR_COLS and TYPE for NUM_COLS.
If you wanted those arrays to have variables like CUSTOMER or BANANA in them then you would have needed to have referenced WORK.BANANA before the ARRAY statements.
So perhaps the data step could start like this:
data column_types;
if 0 then do;
set &libname..&memname ;
array char_cols[*] _character_;
array num_cols[*] _numeric_;
end;
set columns_info;
But note that will cause all kinds of trouble. What happens if the database being checked has a CHARACTER variable name TYPE? That will cause a compile time error for the data step since TYPE is numeric in the COLUMNS_INFO dataset. You cannot have the same variable with two different types in the same dataset.
Is there something you are actually trying to do with these macros (and why did you define the same macro twice? Are there any differences between the two copies of the macro definition?) Can you explain?
Because it really just looks like you are trying to make character variable the the TYPE value as NUM or CHAR instead of numeric values that the TYPE variable generated by PROC CONTENTS has.
data column_types;
set columns_info;
if type=2 then column_type = 'CHAR';
else column_type = 'NUM';
run;
Or perhaps even easier just make a format that maps 1 to NUM and 2 to CHAR and attach it to TYPE and the 1 and 2 will print as NUM and CHAR. Perhaps something like this??
%macro check_column_types_3(libname,memname);
proc contents noprint data=&libname..&memname out=columns_info(keep=name type);
run;
proc format ;
value ctype 1='Num' 2='Char';
run;
proc print data=columns_info;
format type ctype.;
title 'STRAWBERRY BERYRYEYRYRWEBERBE';
run;
proc delete data=columns_info;
run;
%mend check_column_types_3;
%check_column_types_3(libname=work,memname=strawberry);
