add, drop and rename field macros

Reply
Highlighted
Frequent Contributor
Posts: 149

add, drop and rename field macros

[ Edited ]

I wrote these macros to add, drop or rename fields.  Each checks to see if the field already exists.  For addfield, 4th parameter is length for character field or format for numeric field.

 

%macro AddField(ds, field, type, lenfmt);

    %local rc dsid result resx;

    %let dsid = %sysfunc(open(&ds));
    %let resx = %sysfunc(varnum(&dsid, &field));
    %let rc = %sysfunc(close(&dsid));
    %if %upcase(&type)=C %then %let spec=char(&lenfmt); %else %let spec=num;
    
    /*%LET FIND_period = %INDEX(&lenfmt,%str(.)) ;
    %IF %upcase(&type)=N and %eval(&FIND_period) = 0 %THEN %LET lenfmt= &lenfmt.%str(.);*/
    
    %if %upcase(&type)=N and %length(&lenfmt)>1 %then %let lenfmt=%str(format=)&lenfmt; %else %let lenfmt=;

    %if &resx > 0 %then %do;

        %let result = 1;
        %put NOTE: field &field already exists in &ds;

    %end;

    %else %do;

        %let result = 0;
        %put NOTE: field &field does not exist in &ds and will be added;

        proc sql;
            alter table &ds
                add &field &spec &lenfmt
        ;
        quit;    



    %end;
    
%mend AddField;



/* ********************************************************************** */

%macro DropField(ds, field);

    %local rc dsid result resx;

    %let dsid = %sysfunc(open(&ds));
    %let resx = %sysfunc(varnum(&dsid, &field));
    %let rc = %sysfunc(close(&dsid));

    %if &resx > 0 %then %do;

        %let result = 1;
        %put NOTE: field &field exists in &ds and will be dropped;
        proc sql;
            alter table &ds
                drop &field ;
        quit;
    %end;

    %else %do;

        %let result = 0;
        %put NOTE: field &field does not exist in &ds;

    %end;
    
%mend DropField;



/* ********************************************************************** */

%macro RenameField(ds, field, newname);

    %local rc dsid result resx;

    %let dsid = %sysfunc(open(&ds));
    %let resx = %sysfunc(varnum(&dsid, &field));
    %let rc = %sysfunc(close(&dsid));

    %if &resx > 0 %then %do;

        %let result = 1;
        %put NOTE: field &field exists in &ds and will be renamed to &newname ;

        data &ds;
            set &ds;
            /*&newname = &field ;
            drop &field ; */

            rename &field = &newname ;
        run;
        
    %end;

    %else %do;

        %let result = 0;
        %put NOTE: field &field does not exist in &ds;

    %end;
    
%mend RenameField;


Super Contributor
Posts: 284

Re: add, drop and rename field macros

Posted in reply to tomrvincent

what is the issue here? do you have a an ERROR from the log?

Frequent Contributor
Posts: 149

Re: add, drop and rename field macros

No 'issue' at all.  These are macros I wrote that I'm sharing.

Ask a Question
Discussion stats
  • 2 replies
  • 376 views
  • 2 likes
  • 2 in conversation