Help with SAS Macro variable that is a list of regular data set variables

Accepted Solution Solved
Reply
New Contributor
Posts: 2
Accepted Solution

Help with SAS Macro variable that is a list of regular data set variables

Hello everybody!

I was wondering if somebody could help me with my problem.

Basically I have a SAS macro variable which is a list of the variables that are present in a SAS data set and I am cycling through those variables and would like to say cap those variables that are > 254.

Here is the sample code

..... blah-blah-blah... the list of the variable names are put into the sas macro variable called modelvars.

%macro get_capped();

data a;

set b (obs=100);

%let j = 1;

%do %until (%scan(&modelvars.,&j,%str( ))= %str());

   %let var=%upcase(%scan(&modelvars.,&j,%str( )));

     %if &var. > 254 %then &var. = 254;

    %let j = %eval(&j +1);

%end;

run;

%mend get_capped;

%get_capped;

The RED code is the one that I am stuck on. I know that the variable name resolved to TEXT, but how do I make SAS compiler treat that text as if it was the name of the actual variable in the data set and then cap that variable?

Any help would be greatly appreciated!

Thanks!


Accepted Solutions
Solution
‎11-05-2012 05:09 PM
Super User
Posts: 5,518

Re: Help with SAS Macro variable that is a list of regular data set variables

Posted in reply to roman_makordey

On the one hand, you are very close to having a working program.  Getting rid of two % should make it work:

if &var. > 254 then &var. = 254;

On the other hand, this could be solved much more simply, without the need to define a macro.  Consider:

data a;

   set b (obs=100);

   array cap_me {*} &modelvars.;

   do _i_=1 to dim(cap_me);

       if cap_me{_i_} > 254 then cap_me{_i_} = 254;

   end;

run;

Good luck.

View solution in original post


All Replies
Solution
‎11-05-2012 05:09 PM
Super User
Posts: 5,518

Re: Help with SAS Macro variable that is a list of regular data set variables

Posted in reply to roman_makordey

On the one hand, you are very close to having a working program.  Getting rid of two % should make it work:

if &var. > 254 then &var. = 254;

On the other hand, this could be solved much more simply, without the need to define a macro.  Consider:

data a;

   set b (obs=100);

   array cap_me {*} &modelvars.;

   do _i_=1 to dim(cap_me);

       if cap_me{_i_} > 254 then cap_me{_i_} = 254;

   end;

run;

Good luck.

New Contributor
Posts: 2

Re: Help with SAS Macro variable that is a list of regular data set variables

Posted in reply to Astounding

Thank you very much for your help!

Super Contributor
Posts: 1,636

Re: Help with SAS Macro variable that is a list of regular data set variables

Posted in reply to roman_makordey

Hi,

try the code below:

%macro get_capped();

data a;

set b (obs=100);

%let j = 1;

%do %until (%scan(&modelvars.,&j,%str( ))= %str());

   %let var=%upcase(%scan(&modelvars.,&j,%str( )));

    if &var. > 254 then &var. = 254;

    %let j = %eval(&j +1);

%end;

run;

%mend get_capped;

%get_capped;

🔒 This topic is solved and locked.

Need further help from the community? Please ask a new question.

Discussion stats
  • 3 replies
  • 232 views
  • 3 likes
  • 3 in conversation