GPLOT problems with SAS Studio (v 9.4) on Mac

Reply
N/A
Posts: 1

GPLOT problems with SAS Studio (v 9.4) on Mac

Hello!  I am trying to use this newest version of SAS for some really basic GLM work, and the GPLOT command is the only command that doesn't work!  I have attached the code at the bottom, but I only get one error message:

62 proc gplot data=newdata; plot pearson*dose;

ERROR: Procedure GPLOT not found.

Which is weird because when I am typing in the command GPLOT, the helpful little task and snippet bubble completes it for me and gives me syntax.


I'm using a Mac OSX version that is compatible with the software, a VM suggested by SAS, and a browser that is one of the supported browsers.  All of the other commands work just fine, only GPLOT doesn't.


I'm super new to SAS and don't know if this is a "new SAS version" problem or a "user error" issue.


Thanks!

Meaghan


________________________

options nodate nocenter ls=90 ps=60;

data beetle;

input dose killed total; dose2=dose*dose;

cards;

1.6907 6 59

1.7242 13 60

1.7552 18 62

1.7842 28 56

1.8113 52 63

1.8369 53 59

1.8610 61 62

1.8839 59 60

;

proc genmod data=beetle;

model killed/total=dose/dist=bin link=logit;

title 'Logistic Regression using GENMOD';

proc logistic data=beetle; model killed/total=dose/lackfit influence aggregate scale=none covb;

output out=newdata predicted=pre lower=lb upper=ub reschi=pearson3 resdev=deviance;

title 'Logistic Regression using LOGISTIC';

proc gplot data=newdata; plot pearson*dose;

run;

SAS Super FREQ
Posts: 8,721

Re: GPLOT problems with SAS Studio (v 9.4) on Mac


Hi:

  The syntax checker does not check to see what is actually installed. So the GPLOT bubble would have popped up. However, SAS/GRAPH is not included on the University Edition of SAS because ODS GRAPHICS is included with Base SAS and therefore, no extra SAS/GRAPH routines were needed for any of the material that the University Edition is intended for.

  What ! think you can do with your code is to turn ODS GRAPHICS ON; before GENMODE and then turn ODS GRAPHICS OFF; after the PROC LOGISTIC to see whether any of the automatic plots are useful. (Or, look in the doc for the value of PLOTS= to see whether you can ask for any automatic plots of interest.) Otherwise, instead of PROC GPLOT, you'll have to switch to SGPLOT. I am not at a machine with SAS Studio, so  I can't run this code, but it represents just a few tweaks to your code.

  Here's what I did:

1) put in step boundaries (RUNSmiley Happy for each step. Much better to get into the habit of explicitly ending each step with a step boundary. It makes the LOG messages easier to read and avoids trouble with ODS.

2) added PLOTS= to PROC GENMOD and PROC LOGISTIC -- you can find the ODS GRAPHICS documentation has an extensive list of PLOTS= choices you can ask for. I just picked something

3) changed GPLOT to SGPLOT

Cynthia

ods graphics on;
proc genmod data=beetle plots=all;
model killed/total=dose/dist=bin link=logit;
title 'Logistic Regression using GENMOD';
run;

proc logistic data=beetle PLOTS=PHAT;
model killed/total=dose/lackfit influence aggregate scale=none covb;
output out=newdata predicted=pre lower=lb upper=ub reschi=pearson3 resdev=deviance;
title 'Logistic Regression using LOGISTIC';
run;
ods graphics off;
  
proc sgplot data=newdata;
  title 'Using SGPlot';
  scatter y=pearson3 x=dose;
run;
quit;

New Contributor
Posts: 3

Re: GPLOT problems with SAS Studio (v 9.4) on Mac

dear ;

Did you solve the problem? I went to share your experience because I faced the same problem.

thanks

Ask a Question
Discussion stats
  • 2 replies
  • 5815 views
  • 0 likes
  • 3 in conversation