Embed SGPLOT and Proc Report in Email

Reply
Frequent Contributor
Posts: 89

Embed SGPLOT and Proc Report in Email

 

I am trying to embed a SGPLOT chart as a png a PROC REPORT table as HTMl in the body of the same email, I can get one or the other to work but not both together (code below sends as 2 emails).  Any ideas to embed them both in the same email?  Do I need to convert the PROC REPORT to a png as well?

 

%let workdir=%trim(%sysfunc(pathname(work)));
ods _ALL_ close; 
ods listing gpath="&workdir";
ods graphics / reset=index width=16in height=6in outputfmt=PNG imagename='Chart';  

proc sgplot data=Weekly;
	series x=week y=Metric;
run;

filename sendmail email 
	to=("") 
	from=("")
	attach=("&workdir./Chart.png" inlined='sgplot')
	type='text/html' subject="Weekly Summary";

data _null_;
	file sendmail;  
	put '<html>';
	put '<body>';
	put '<img src=cid:sgplot>';
	put '</body>';
	put '</html>';
run; 

ODS LISTING CLOSE;
ODS HTML BODY=sendmail;

proc report data = Weekly center style=seasideprinter;
	column ('Week Ending' week), Metric;
	define week / across ' ';
	define Metric / analysis sum f=comma6. ' ';
run;

ODS HTML CLOSE;
ODS LISTING;

filename sendmail clear;

 

Super User
Posts: 10,259

Re: Embed SGPLOT and Proc Report in Email

Omit the data _null_ step, but use ods text:

ODS HTML BODY=sendmail;

ods text='<img src=cid:sgplot>';

proc report data = Weekly center style=seasideprinter;
	column ('Week Ending' week), Metric;
	define week / across ' ';
	define Metric / analysis sum f=comma6. ' ';
run;

ODS HTML CLOSE;
---------------------------------------------------------------------------------------------
Maxims of Maximally Efficient SAS Programmers
How to convert datasets to data steps
How to post code
Ask a Question
Discussion stats
  • 1 reply
  • 56 views
  • 0 likes
  • 2 in conversation