Hi everyone,
I would like to generate all possible combinations of three variables each with values 0 or 1 e.g. following using a data step
000
001
010
100
011
101
110
111
what will be a good way to do it?
So maybe something like this.
data want;
array p[2] _temporary_ (0 1);
array x[3];
do _n_=0 to dim(p)**dim(x)-1;
do i=1 to dim(x);
x(i)=p(1+mod(int(_n_/(dim(p)**(i-1))),dim(p))) ;
end;
output;
end;
drop i ;
run;
Check out the ALLCOMB function in SAS. Designed just for such a thing!
Thanks, it's a nice function. But the problem is I have n=2 (0 or 1) but k=3 which doesn't work for ALLCOMB.
A not terribly bright solution
data _null_; do i='0','1'; do j='0','1'; do k='0','1'; comb=cats(i,j,k); put comb=; end; end; end; run;
These combinations are just a sequence of binary numbers. You don't need any data to do that:
data want;
do i=0 to 7;
result = put(i, binary3.);
output;
end;
drop i;
run;
Thanks, this is a nice little trick. I will have to have 3 different columns for all combinations of 0 or 1.
For three it is simple.
data want;
do a=0,1; do b=0,1; do c=0,1;
output;
end; end; end;
run;
Not sure what you are talking about at this point. If you have four variables named P, X1 , X2, and X3 then you could build all combinations using similar DO loops. If you have two tables and want to join them to produce all possible combinations then PROC SQL does a good job.
proc sql ;
create table want as
select *
from P, X
;
quit;
If you really have two vectors and what to manipulate them then use PROC IML. You can do lots of matrix manipulation using a language designed to work with matrices.
So maybe something like this.
data want;
array p[2] _temporary_ (0 1);
array x[3];
do _n_=0 to dim(p)**dim(x)-1;
do i=1 to dim(x);
x(i)=p(1+mod(int(_n_/(dim(p)**(i-1))),dim(p))) ;
end;
output;
end;
drop i ;
run;
Don't miss out on SAS Innovate - Register now for the FREE Livestream!
Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.